!***************************************************************************************************!
! TITLE: CFVR2709 - Shear checking according to AS3600
! SUBTITLE: Check a reinforced concrete beam subjected to shear force according to AS3600
!
! DESCRIPTION: A beam which is fixed at the right and simply supported at the left,
! DESCRIPTION: has a rectangular concrete reinforced section
! DESCRIPTION: and it is subjected to a uniform distributed load of 6.75 Mp/m.
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to obtain the check criterion according to AS3600.
!
! ELEMENT TYPE: BEAM3
! MODULES:
! UNITS: User
! KEYWORD1: Beam
! KEYWORD2: Cross Section
! KEYWORD3: Code Checking/Design
! KEYWORD4: Reinforced Concrete
! KEYWORD5: AS3600
!
!***************************************************************************************************!
 FINISH
 ~CFCLEAR,,1

 NomFile='CFVR2709'
 /TITLE,%NomFile%, SHEAR CHECKING ACCORDING TO AS3600

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~UNITS,,LENG,M
~UNITS,,TIME,S
~UNITS,,FORC,MP
~CODESEL,EC3-92,AS3600,,,EC8-94

! Preprocessor
  /PREP7

! Parameters
  L=10         ! Length between supports, in m
  b=.3         ! Cross-section width in m.
  h=.5         ! Depth in m.
  Q=4.5*1.5    ! Uniform distributed load in Mp/m

! Material Definition
 ~CFMP,3,LIB,CONCRETE,ACI,fc_4500
 ~CFMP,4,LIB,REINF,ACI,fy_60000

! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,2,REC,3,0.5,0.3

! Reinforcement definition
 ~RNFDEF,2,1,4,4,,,0.6368E-02     ! Bot. reinf. for bending
 ~RNFDEF,2,2,4,2,,,0.2283E-02     ! Top reinf. for bending
 ~RNFDEF,2,SHEAR,4,,,.00128 ! Shear reinf.
! Code properties definition
 ~SECMDF,2,AS3600PR,REC,,5e-002
! Beam properties
 ~BMSHPRO,1,BEAM,2,2,,,3,0,0,Beam properties

! Model
  MAT,3
  N,1                                   ! Nodes input
  N,21,L
  FILL,1,21
  E,1,2                                 ! Elements input
  EGEN,20,1,1,1
  D, 1, , , , , ,UX,UY                  ! Boundary conditions
  D,21, , , , , ,UY

FINISH
/SOLU                 ! Entering the solution processor
  SFBEAM,ALL,1,PRES,Q
  f,10,fx,20
  f,21,fx,-10
  SOLVE               ! Calculation

FINISH
/POST1                ! Entering the postprocessor
! Postprocessor
  ~CFSET,,1,1         ! Read first load step
! Shear in Y checking
  ~CHKCON,SHT,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 11
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VUMAX'
  LABEL(2,1) = 'BETA1'
  LABEL(3,1) = 'BETA2'
  LABEL(4,1) = 'VUC'
  LABEL(5,1) = 'VUS'
  LABEL(6,1) = 'VU'
  LABEL(7,1) = 'CRTVUMAX'
  LABEL(8,1) = 'CRTVU'
  LABEL(9,1) = 'CRT_TOT'
  LABEL(10,1) = 'BETA2'
  LABEL(11,1) = 'VUC'

! Correct values
  VALUE(1,1)=86.038
  VALUE(2,1)=1.265
  VALUE(3,1)=1.046698333
  VALUE(4,1)=7.492416176
  VALUE(5,1)=24.2980
  VALUE(6,1)=31.79040018
  VALUE(7,1)=0.56031
  VALUE(8,1)=1.516630349
  VALUE(9,1)=1.516630349
  VALUE(10,1)=0.813206667
  VALUE(11,1)=5.821049475

! Comparison
  ~CFGET,VALUE(1,2),ELEMENT,20,RESULT,VUMAX,J
  ~CFGET,VALUE(2,2),ELEMENT,20,RESULT,BETA1,J
  ~CFGET,VALUE(3,2),ELEMENT,20,RESULT,BETA2,J
  ~CFGET,VALUE(4,2),ELEMENT,20,RESULT,VUC,J
  ~CFGET,VALUE(5,2),ELEMENT,20,RESULT,VUS,J
  ~CFGET,VALUE(6,2),ELEMENT,20,RESULT,VU ,J
  ~CFGET,VALUE(7,2),ELEMENT,20,RESULT,CRTVUMAX,J
  ~CFGET,VALUE(8,2),ELEMENT,20,RESULT,CRTVU  ,J
  ~CFGET,VALUE(9,2),ELEMENT,20,RESULT,CRT_TOT,J
  ~CFGET,VALUE(10,2),ELEMENT,1,RESULT,BETA2,I
  ~CFGET,VALUE(11,2),ELEMENT,1,RESULT,VUC,I

! Warning and error tolerances
  *DO,II,1,NComp
    TOLER(II, 1)= 1E-2 $ TOLER(II, 2)= 1E-2
  *ENDDO

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC