!*************************************************************************************!
! TITLE: CFVR3703 - Effective stresses
! SUBTITLE: Effective stresses on a 2D Model with irregular mesh.
!
! DESCRIPTION: A plane model is used to analyze the effective stresses obtained when
! DESCRIPTION: applying the seepage results on a structural analysis.
! DESCRIPTION:
! DESCRIPTION: The seepage model is a 5.0m x 6.0 m rectangle and the structural model
! DESCRIPTION: is a is a 5.0 m x 10.0 m rectangle.
!
! ELEMENT TYPE: PLANE42
! MODULES: GETC
! UNITS: SI
! KEYWORD1: Geotechnics
!*************************************************************************************!
! -------------------------------------------------------------------------------------
!
! SEEPAGE ANALYSIS
!
! -------------------------------------------------------------------------------------
FINISH
~CFCLEAR,,1
~CFACTIV,GETC,Y
~UNITS,,FORC,KN

NomFile='CFVR3703'
/TITLE, %NomFile%, Effective stresses

~SEEPAGE,2D

/PREP7
~CFMP,1,LIB,SOIL,,MH

! Rectangle B*H
H = 6
B = 5
! Relative location of the rectangle
XR = 0
YR = 0
K,1,XR,YR
K,2,XR+B,YR
k,3,XR+B,YR+H
k,4,XR,YR+H
!
A,1,2,3,4
ESIZE,H/10
MSHAPE,1
AMESH,ALL
!
DL,1,,HEAD,H*10.0
DL,3,,HEAD,H
!
/SOLU
~LPSOLVE
!
/POST1
file,file,seep
SET,LAST
~WTSLP

! -------------------------------------------------------------------------------------
!
! STRUCTURAL ANALYSIS
!
! -------------------------------------------------------------------------------------
FINISH
~CFCLEAR,,1
~UNITS,,FORC,KN
NomFile='CFVR3703'
/TITLE, %NomFile%, Effective stresses
!

/DFLAB,1,UX
/PREP7
~CFMP,1,LIB,SOIL,,MH
~CFMP,1,DatGen,RHO,,1000
ET,1,PLANE42,,,2   ! Structural Solid
! Rectangle B*H
H = 10
B = 5
! Relative location of the rectangle
XR = 0
YR = 0
K,1,XR,YR
K,2,XR+B,YR
k,3,XR+B,YR+H
k,4,XR,YR+H

A,1,2,3,4
ESIZE,H/10
AMESH,ALL

/SOLU
DL,1,,UY,0
DL,2,,UX,0
DL,4,,UX,0

ACEL,0,10,0
SOLVE

/POST1

SET,LAST
PLNSOL,S,Y

~EFFPRES,Y
PLNSOL,S,Y
NSEL,S,LOC,X,0

! -------------------------------------------------------------------------------------
! DATA CHECK
! -------------------------------------------------------------------------------------
! Data comparison number
  NComp    = 11
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Correct data, obtained data
! -------------------------------------------------------------------------------------
*DIM,VNodes,ARRAY,11
*DIM,SMED,ARRAY,12
*DIM,SNOD,ARRAY,11
*DIM,UNOD,ARRAY,11

*DO,II,2,11
  ! Gravity stress at intermediate Points (CENTROIDS)
  SMED(II) = (10*(II-2)+5)*1000
*ENDDO
SMED(1) = SMED(2)
SMED(12)= SMED(11)

*DO,II,1,11
  ! Interpolation to nodes
  SNOD(II)= (SMED(II)+SMED(II+1))/2.0
*ENDDO

*DO,II,1,5
  unod(ii)=0.0
*enddo
*DO,II,5,11
  ! Pore pressures
   UNOD(II)=10*(II-5)*60./6.
*ENDDO
*DO,II,1,11
  ! Interpolation to nodes
  VALUE(II,1)= ABS(SNOD(ii))-UNOD(II)
*ENDDO

VNodes(1) = 17,22,23,24,25,26,27,28,29,30,1
*DO,II,1,11
  *GET,VALUE(II,2),NODE,VNodes(II),S,Y
*ENDDO

! Labels
! -------------------------------------------------------------------------------------
*DO,II,1,11
   LABEL(II)  = 'P%II%'
*ENDDO

! Warning and error tolerances
*DO,II,1,11
  TOLER(II,1) = 50
  TOLER(II,2) = 50
*ENDDO

! -------------------------------------------------------------------------------------
! Results comparison
! -------------------------------------------------------------------------------------
  COMPARA.MAC