!*************************************************************************************!
! TITLE: CFVR5243 - Primary and secondary forces and moments on isostatic beam
! SUBTITLE: T cross section.
!
! DESCRIPTION: The model is a prestressed beam 15 m length.
! DESCRIPTION:
! DESCRIPTION: The beam is made of C16/20 concrete and the tendons are made of Gr250 steel.
! DESCRIPTION:
! DESCRIPTION: The section is a T one with reinforcement of S400 steel.
! DESCRIPTION: It has the following dimensions:
! DESCRIPTION:
! DESCRIPTION: - h = 1 m
! DESCRIPTION:
! DESCRIPTION: - tw = 0.5 m
! DESCRIPTION:
! DESCRIPTION: - b = 1 m
! DESCRIPTION:
! DESCRIPTION: - tf = 0.3 m
! DESCRIPTION:
! DESCRIPTION: Loads:
! DESCRIPTION:
! DESCRIPTION: - Self weight
! DESCRIPTION:
! DESCRIPTION: - Prestressing loads
! DESCRIPTION:
! DESCRIPTION: The aim of the example is to verify the calculation of primary and
! DESCRIPTION: secondary forces and moments .
!
! ELEMENT TYPE: BEAM44
! MODULES: PRSC
! UNITS: SI
! KEYWORD1: Beam
! KEYWORD2: Tendon
! KEYWORD3: Cross Section
! KEYWORD4: Prestressed Concrete
! KEYWORD5: Prestressing Losses
!
!*************************************************************************************!
   FINISH
   ~CFCLEAR,,1
   ~CFACTIV,PRSC,Y
   NomFile='CFVR5243'
 /TITLE,%NomFile%, I&H CHECKING, ISOST BEAM, T SECTION

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,SI
  ~CODESEL,,EC2-91,EC2-91
  ~CFACTIV,PRSC,Y

! Preprocessor
  /PREP7

! Material Definition
  ~CFMP,1,LIB,CONCRETE,EC2,C16/20
  ~CFMP,2,LIB,REINF,CEB,S400
  ~CFMP,3,LIB,PREST,ASTMA416,Gr250

! Element Type Definition
  ET,1,Beam44

! Cross-section definition
  ~CSECDMS,1,T,1,1 ,0.5,1 ,0.3,0 ,0 ,0 ,0 ,2 ,2
! Beam & Shell property
  ~BMSHPRO,1,BEAM,1,1,,,44,1,1,,Beam 1

! Model Construction
  k,1
  k,2,15
  l,1,2
  dk,1,ux,0,,,uy,uz,rotx
  dk,2,uy,0,,,uz
  h_elems = 4
  medcut = h_elems+1
  endcut   = h_elems*2+1
  lesize,all,,,h_elems*2
  lmesh,all

! Support beam construction
  area = 0.01
  c_diameter = 0.15
  ~SBBMDEF

  ~PCEPDEF,1,       1,-0.200,0
  ~PCEPDEF,2,  medcut,-0.200,0
  ~PCEPDEF,3,  endcut,-0.200,0

  ~PCPPDEF,1,       1,     0,0
  ~PCPPDEF,3,  endcut,     0,0

  Papp = 2e7
  ~PCTNDEF,1,3,area,c_diameter,Papp ,Papp ,0

  ~PCTNMDF,1,EADD,1.
  ~PCTNMDF,1,EADD,2.
  ~PCTNMDF,1,EADD,3.
  ~PCTNMDF,1,PADD,1.
  ~PCTNMDF,1,PADD,3.
  ~PCTNMDF,1,METHOD,1

  ~PCTNMDF,1,EPAROUT,1,0
  ~PCTNMDF,1,EPARIN,2,0

/SOLU
  ~PCPL               ! Prestressing forces
  SOLVE               ! Calculation

/POST1

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number

  NComp = 15
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels, Correct data, obtained data
!--------------------------------------------------------------------------------------
  ~CFSET,,1
  LABEL( 1) = 'KPRES1' $  VALUE( 1,1) =  1         $  ~CFGET,VALUE( 1,2),PRSCONC,,KPRES
                                   ~CFGET,aux1,ELEMENT,h_elems,FORCE, MZ,J,
                                   ~CFGET,aux2,ELEMENT,h_elems,FORCE,IMZ,J,
  LABEL( 2) = 'MZ/IMZ' $  VALUE( 2,1) =  1         $  VALUE( 2,2)=aux1/aux2
                                   ~CFGET,aux1,ELEMENT,h_elems,FORCE, FX,J,
                                   ~CFGET,aux2,ELEMENT,h_elems,FORCE,IFX,J,
  LABEL( 3) = 'FX/IFX' $  VALUE( 3,1) =  1         $  VALUE( 3,2)=aux1/aux2
                                   ~CFGET,aux1,ELEMENT,h_elems,FORCE,HFY,J,
                                   ~CFGET,aux2,ELEMENT,h_elems,FORCE,IFY,J,
  LABEL( 4) = 'HFY'     $ VALUE( 4,1) =  0.0         $  VALUE( 4,2)=ABS(aux1)
  LABEL( 5) = 'RFX1'    $ VALUE( 5,1) =  0.0         $  *GET,VALUE( 5,2),NODE,1,RF,FX
  LABEL( 6) = 'RFY1'    $ VALUE( 6,1) =  0.0         $  *GET,VALUE( 6,2),NODE,1,RF,FY
  LABEL( 7) = 'RFZ1'    $ VALUE( 7,1) =  0.0         $  *GET,VALUE( 7,2),NODE,1,RF,FZ
  LABEL( 8) = 'RFY2'    $ VALUE( 8,1) =  0.0         $  *GET,VALUE( 8,2),NODE,2,RF,FY
  LABEL( 9) = 'RFZ2'    $ VALUE( 9,1) =  0.0         $  *GET,VALUE( 9,2),NODE,2,RF,FZ
  LABEL(10) = 'FX'      $ VALUE(10,1) = -Papp        $  ~CFGET,VALUE(10,2),ELEMENT,h_elems,FORCE,FX,J,
  LABEL(11) = 'FY'      $ VALUE(11,1) =  0.0         $  ~CFGET,VALUE(11,2),ELEMENT,h_elems,FORCE,FY,J,
  LABEL(12) = 'FZ'      $ VALUE(12,1) =  0.0         $  ~CFGET,VALUE(12,2),ELEMENT,h_elems,FORCE,FZ,J,
  LABEL(13) = 'MX'      $ VALUE(13,1) =  0.0         $  ~CFGET,VALUE(13,2),ELEMENT,h_elems,FORCE,MX,J,
  LABEL(14) = 'MY'      $ VALUE(14,1) =  0.0         $  ~CFGET,VALUE(14,2),ELEMENT,h_elems,FORCE,MY,J,
                                   ~CFGET,aux1,SECTION,1,STRPROP,YCG,,5
  LABEL(15) = 'MZ'      $ VALUE(15,1) =  Papp*(aux1-0.2) $  ~CFGET,VALUE(15,2),ELEMENT,h_elems,FORCE,MZ,J,

! Warning and error tolerances
  TOLER(  1,1) = 1E-03   $  TOLER(  1,2) = 1E-03
  TOLER(  2,1) = 1E-03   $  TOLER(  2,2) = 1E-03
  TOLER(  3,1) = 1E-03   $  TOLER(  3,2) = 1E-03  
  TOLER(  4,1) = 1E-03   $  TOLER(  4,2) = 1E-03
  TOLER(  5,1) = 1E-03   $  TOLER(  5,2) = 1E-03
  TOLER(  6,1) = 1E-03   $  TOLER(  6,2) = 1E-03
  TOLER(  7,1) = 1E-03   $  TOLER(  7,2) = 1E-03
  TOLER(  8,1) = 1E-03   $  TOLER(  8,2) = 1E-03
  TOLER(  9,1) = 1E-03   $  TOLER(  9,2) = 1E-03
  TOLER( 10,1) = 1E-03   $  TOLER( 10,2) = 1E-03
  TOLER( 11,1) = 1E-03   $  TOLER( 11,2) = 1E-03
  TOLER( 12,1) = 1E-03   $  TOLER( 12,2) = 1E-03
  TOLER( 13,1) = 1E-03   $  TOLER( 13,2) = 1E-03
  TOLER( 14,1) = 1E-03   $  TOLER( 14,2) = 1E-03
  TOLER( 15,1) = 1E-03   $  TOLER( 15,2) = 1E-03

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC