第
8章
杂项工具
8.1 结构的成本和重量
8.1.1 成本
根据所用材料的单位体积成本值，CivilFEM 计算组成结构的每个单元的成本。
这样得到的成本是结构实际成本的近似值，因为未考虑复杂结构的具体细节或最终精确几何形状。但是，在优化计算中非常有用，因为这类计算旨在从总体上最小化结构的总成本。
每个单元的成本按以下方式计算：
- 实体单元（SOLID）：单元体积乘以组成该单元的材料的单位体积成本。
- 梁单元（BEAM, LINK）：根据组成截面的不同材料及其在分块和板片中的离散方式计算横截面的成本，并采用毛截面而非有效截面的计算公式。单元总成本等于两个截面成本的算术平均值（每个端部一个）乘以单元长度。
- 板单元（SHELL）：与梁单元一样，计算每个端部（板顶点）的成本，其中加入混凝土板配筋量的成本，然后对整个单元进行加权。
剪切和扭转配筋（梁或板）不计入成本计算。
可以按材料分项显示成本（命令 ~COSTLST），也可以在计算中将其作为数值使用（命令 ~COST).
使用 ANSYS 通用材料划分网格的单元，不计入结构成本计算。
8.1.2 重量
有时可能需要了解结构的重量。可以通过以下两种方式实现：
- 根据结构的几何形状和材料密度。
- 求解后，将支座上的反力相加。
当使用节点之间的位移协调方程、倾斜支座等时，第二种方法可能导致理解错误。
第一种方法可通过命令 ~WEIGHT直接应用。其计算过程与结构成本计算所述过程相同，但使用材料的重度代替单位体积成本。
使用 ANSYS 通用材料划分网格的单元，不通过此方法计入结构重量计算。
8.2 影响线
8.2.1 适用范围和限制
对于采用 BEAM188 和 BEAM189 单元建立模型的 2D 和 3D 杆结构，可以获得影响线。
对于给定的 3D 结构，最多可以获得 36 条影响线，这是由六种内力中的任意一种组合产生的 目标 (FX、FY、FZ、MX、MY、MZ)，对应六种可能的作用（FX、FY、FZ、MX、MY、MZ）。 对于二维结构，可能的影响线数量为九条（FX、 FY、MZ）相对于（FZ、MY、MZ）。
单元方向的定义必须通过第三个节点 完成K.
需要指出的是，内力和目标， 荷载作用始终均以节点坐标系为基准。
为获得该结果，CivilFEM 在 Müller-Breislau 公式中采用互易原理，因此需要暂时改变结构。
由于其性质，影响线只能针对与两根杆件相连的节点提出要求，且只能是两根。
8.2.2 影响线的打开与关闭
如上一节所述，为获得影响线，需要修改初始结构：释放 自由度、解除梁的连接等。
创建影响线时，CivilFEM 将修改结构 （打开影响线，命令 ~ILOPEN) 并允许在计算完成后立即恢复其初始几何形状和条件，或在一段时间后恢复（命令 ~ILCLOSE），以便对影响线结果进行 后处理。
8.2.3 装配体
打开影响线时，将创建以下 装配体:
- CFInfLine%ILID%正值
- CFInfLine%ILID%负值
其中，%LID%为所创建影响线的编号。
这些 荷载组包含节点和单元，其中作用于节点或单元上的荷载（力、弯矩或压力）会对目标应力产生正面或负面影响。
需要特别指出的是，作用于梁单元上的压力沿其法线方向作用，其方向取决于单元轴（因此也取决于节点 I、J、K 的位置），所以建议在定义压力时特别注意其与节点轴的关系。
8.2.4 示例
8.2.4.1 说明
为便于在 CivilFEM 中使用影响线，准备了五个示例，并在以下各节中附有图形和 File-Logs:
- 示例 1
这是一个具有五个跨度的水平连续梁，需要求得跨中某一点处弯矩和剪力的影响线。
作用为竖向力 FY。
本示例与下一个示例都非常简单，用于初步了解该功能。
- 示例 2
在上述同一结构中，求得支座处某一点的弯矩和剪力影响线，作用仍为竖向力 FY。
- 示例 3
现在结构为平面两端固结拱，求得其中部偏心某一点处的弯矩、剪力和轴力影响线。
作用为垂直于拱轴线的力。
本示例的重点主要在于节点坐标的使用。
- 示例 4
某一特定的超载可按相应示意图所示的方式作用于平面刚架，也可不作用。
需要求得使某一点产生最大负弯矩的荷载分布。
本示例再次使用节点坐标的概念，但现在需要将其与单元坐标协调起来。
得到影响线后，加载包含 产生节点负弯矩的单元的荷载组，然后求解结构。
本示例还涉及容差（NEGTOL）的使用。建议读者为该字段设置不同的值进行练习。
- 示例 5
最后一个示例采用位于一个平面内的三维结构，荷载沿 –Z 方向垂直于该平面作用。
现在的目的是确定扭矩的影响线。
8.2.4.2 示例 1. 五跨连续梁
图示
LOG
!
! 示例 1：影响线 - 5 跨连续梁
! 目标：第一跨跨中点
FINISH
~CFCLEAR,,1
/TITLE, 'CivilFEM 生成的影响线：连续梁（I）'
~CODESEL,EC3,EC2 ! 设置欧洲 规范
~UNITS,SI ! 设置 国际单位制单位
/PREP7
!
! =========================== STEP 1: STRUCTURE DEFINITION
!
! 单元类型
ET,1,BEAM188,,,2
! 材料：EC3-Steel
~CFMP,10,LIB,STEEL,EC3,Fe 360
! 梁截面
~SSECLIB,1,1,1,16 ! IPE 500（H 形）
~SECMDF,1,ROTATE,,,90 ! IPE 500 旋转
~BMSHPRO,1,BEAM,1,1,,,188,0,0,,梁 1
! 实体建模
TYPE,1 $ MAT,10 $ SECNUM,1
K,1
K,2,2
K,3,4
K,4,8
K,5,12
K,6,16
K,7,20
K,100, 100, 100 ! BEAM188 K-方向点
! 边界条件 I：铰支座
DK,1,ux,0 $ DK,1,uy,0
DK,3,ux,0 $ DK,3,uy,0
DK,4,ux,0 $ DK,4,uy,0
DK,5,ux,0 $ DK,5,uy,0
DK,6,ux,0 $ DK,6,uy,0
DK,7,ux,0 $ DK,7,uy,0
L,1,2 ! 直线 1
L,2,3 ! 2
L,3,4 ! 3
L,4,5 ! 4
L,5,6 ! 5
L,6,7 ! 6
! 划分网格
ESIZE,0.5 ! 单元尺寸
LATT,ALL,10,,1,,100,,1
LMESH,ALL
! 边界条件 II：平面结构
D,ALL,UZ,0
D,ALL,ROTX,0
D,ALL,ROTY,0
NSEL,ALL $ ESEL,ALL
!
! =========================== STEP 2: INFLUENCE LINE CALCULATION
!
! 目标节点
nn=NODE(kx(2),ky(2),0)
! 弯矩影响线 -----------------------------------------------
~ILOPEN,5,MZ,FY,nn,,,,1
/POST1
! 创建影响线图形
/DSCA,ALL,10
PLDISP,2
/PREP7
! 闭合影响线
! 剪力影响线 -----------------------------------------------
~ILOPEN,5,FY,FY,nn,,,,1
/POST1
! 创建影响线图形
/DSCA,ALL,10
PLDISP,2
/PREP7
! 闭合影响线
8.2.4.3 示例 2. 五跨连续梁
图示
LOG
!
! 示例 2：影响线 - 5 跨连续梁
! 目标点：支座
FINISH
~CFCLEAR,,1
/TITLE, 'CivilFEM影响线：连续梁（II）'
~CODESEL,EC3,EC2 ! 设置欧洲 规范
~UNITS,SI ! 设置 国际单位制单位
/PREP7
!
! =========================== STEP 1: STRUCTURE DEFINITION
!
! 单元类型
ET,1,BEAM188,,,2
! 材料：EC3-Steel
~CFMP,10,LIB,STEEL,EC3,Fe 360
! 梁截面
~SSECLIB,1,1,1,16 ! IPE 500（H 形）
~BMSHPRO,1,BEAM,1,1,,,188,0,0,,梁 1
! 实体 建模
TYPE,1 $ MAT,10 $ SECNUM,1
K,1
K,2,2
K,3,4
K,4,8
K,5,12
K,6,16
K,7,20
K,100, 100, 100 ! BEAM188 K-方向点
! 边界条件 I：铰支座
DK,1,ux,0 $ DK,1,uy,0
DK,3,ux,0 $ DK,3,uy,0
DK,4,ux,0 $ DK,4,uy,0
DK,5,ux,0 $ DK,5,uy,0
DK,6,ux,0 $ DK,6,uy,0
DK,7,ux,0 $ DK,7,uy,0
L,1,2 ! 线 1
L,2,3 ! 2
L,3,4 ! 3
L,4,5 ! 4
L,5,6 ! 5
L,6,7 ! 6
! 网格划分
ESIZE,0.5 ! 单元尺寸
LATT,ALL,10,,1,,100,,1
LMESH,ALL
! 边界条件 II：平面结构
D,ALL,UZ,0
D,ALL,ROTX,0
D,ALL,ROTY,0
NSEL,ALL $ ESEL,ALL
!
! =========================== STEP 2: INFLUENCE LINE CALCULATION
!
! 目标节点
nn=NODE(kx(3),ky(3),0)
! 弯矩影响线 -----------------------------------------------
~ILOPEN,5,MZ,FY,nn,,,,1
/POST1
! 创建影响线图形
/DSCA,ALL,10
PLDISP,2
/PREP7
! 关闭影响线
! 剪力影响线 -----------------------------------------------
~ILOPEN,5,FY,FY,nn,,,,1
! 创建影响线图形
/POST1
/DSCA,ALL,10
PLDISP,2
/PREP7
! 关闭 影响线
8.2.4.4 示例 3. 平面两端固结拱
示意图
LOG
!
! 示例 3：影响线 - 固端圆拱
!
FINISH
~CFCLEAR,,1
/TITLE, 'CivilFEM影响线：拱'
~CODESEL,EC3,EC2 ! 设置欧洲 规范
~UNITS,SI ! 设置 国际单位制单位
/PREP7
!
! =========================== STEP 1: STRUCTURE DEFINITION
!
! 单元类型
ET,1,BEAM188,,,2
! 材料：EC3-Steel
~CFMP,10,LIB,STEEL,EC3,Fe 360
! 梁截面
~SSECLIB,1,1,1,16 ! IPE 500（H 形）
~SECMDF,1,ROTATE,,,90 ! IPE 500 旋转（工字形）
~BMSHPRO,1,BEAM,1,1,,,188,0,0,,梁 1
! 实体建模
TYPE,1 $ MAT,10 $ SECNUM,1
*AFUN,DEG ! 使用角度制
K, 1, 6*COS(150),6*SIN(150)
K, 2, 6*COS(120),6*SIN(120)
K, 3, 6*COS( 30),6*SIN( 30)
K,100, 0, 0 ! BEAM188 K-方向点
*AFUN,RAD ! 使用弧度制
LARC,1,2,3,6.0001
LARC,2,3,1,6.0001
! 边界条件 I；拱端固结。
DK,1,ALL,0
DK,3,ALL,0
! 网格划分
ESIZE,0.5 ! 单元尺寸
LATT,ALL,10,,1,,100,,1
LMESH,ALL
! 边界条件 II：平面结构
D,ALL,UZ,0
D,ALL,ROTX,0
D,ALL,ROTY,0
NSEL,ALL $ ESEL,ALL
! 旋转节点
CSYS,2 ! 柱坐标系
NROT,ALL ! X-> 径向 Y-> 切向
CSYS,0 ! 默认笛卡尔坐标系
!
! =========================== STEP 2: INFLUENCE LINE CALCULATION
!
! 目标节点
nn=NODE(kx(2),ky(2),0)
! 弯矩影响线 -----------------------------------------------
~ILOPEN,5,MZ,FX,nn,,,,1
/POST1
! 创建影响线图形
/DSCA,ALL,-1
PLDISP,2
/PREP7
! 结束影响线
! 剪力影响线 -----------------------------------------------
~ILOPEN,6,FX,FX,nn,,,,1
/POST1
! 创建影响线图形
/DSCA,ALL,-1
PLDISP,2
/PREP7
! 结束影响线
! 轴力影响线 -----------------------------------------------
~ILOPEN,7,FY,FX,nn,,,,1
/POST1
! 创建影响线图形
/DSCA,ALL,-1
PLDISP,2
/PREP7
! 结束影响线
8.2.4.5 示例 4. 平面刚架
图示
LOG
!
! 示例 4：影响线 - 三杆件框架
!
FINISH
~CFCLEAR,,1
/TITLE, 'CivilFEM 影响线：刚架'
~CODESEL,EC3,EC2 ! 设置欧洲 规范
~UNITS,SI ! 设置 国际单位制
/PREP7
!
! =========================== STEP 1: STRUCTURE DEFINITION
!
! 元素类型
ET,1,BEAM188,,,2
! 材料：EC3-Steel
~CFMP,10,LIB,STEEL,EC3,Fe 360
! 梁截面
~SSECLIB,1,1,1,16 ! IPE 500（H 形）
~SECMDF,1,ROTATE,,,90 ! IPE 500 旋转（I形）
~BMSHPRO,1,BEAM,1,1,,,188,0,0,,梁 1
! 实体建模
TYPE,1 $ MAT,10 $ SECNUM,1
K,1
K,2,0,5
K,4,6,2
K,5,6,7
K,3,(KX(2)+KX(5))/2,(KY(2)+KY(5))/2
K,6,12,0
K,100, 100, 100 ! BEAM188 K-方向点（线 2 和 3）
K,101,-100, 100 ! BEAM188 K-方向点（线 1 和 4）
! 边界条件 I：铰支座
DK,1,ux,0 $ DK,1,uy,0 $ DK,1,rotz,0
DK,4,ux,0 $ DK,4,uy,0 $ DK,4,rotz,0
DK,6,ux,0 $ DK,6,uy,0 $ DK,6,rotz,0
L,1,2 ! 线 1
L,2,3 ! 2
L,3,5 ! 3
L,4,5 ! 4
L,5,6 ! 5
! 不同方向的网格划分
ESIZE,1 ! 单元尺寸
LSEL,S,LINE,,2,3
LSEL,A,LINE,,5
LATT,ALL,10,,1,,100,,1
LMESH,ALL
LSEL,A,LINE,,1,4,3
LATT,ALL,10,,1,,101,,1
LMESH,ALL
! 边界条件 II：平面框架
D,ALL,UZ,0
D,ALL,ROTX,0
D,ALL,ROTY,0
NSEL,ALL
! 目标节点
nn=NODE(kx(3),ky(3),0)
! 节点旋转
LSEL,S,LINE,,1 ! 竖向支座
LSEL,A,LINE,,4
NSLL,S,0
NMODIF,ALL,,,,90,0,0
LSEL,S,LINE,,2,3 ! 过梁
NSLL,S,0
NSEL,A,NODE,,nn
Angle1=ATAN( (KY(5)-KY(2))/(KX(5)-KX(2)) )*180/3.14159265 ! lintel slope
NMODIF,ALL,,,,Angle1,0,0
LSEL,S,LINE,,5 ! 斜支座
NSLL,S,0
Angle2=ATAN2(KY(5)-KY(6), KX(5)-KX(6))*180/3.14159265 ! support slope
NMODIF,ALL,,,,Angle2,0,0
NSEL,ALL
!
! =========================== STEP 2: INFLUENCE LINE CALCULATION
!
~ILOPEN,10,MZ,FY,nn,,,,1,0.001,0.001
/POST1
! 创建影响线图形
/DSCA,ALL,2
PLDISP,2
RSYS,SOLU
/GRAPHICS,FULL
PLNSOL,U,Y
/PREP7
! 关闭影响线
!
! =========================== STEP 3: STRUCTURE CALCULATION
!
! 结构加载
CMSEL,S,CFInfLine10_NEGATIVE ! 过梁负弯矩的组件
SFBEAM,ALL,1,PRES,100000
ESEL,ALL
NSEL,ALL
! 结构计算
/SOLU
SOLVE
! 弯矩绘图
/POST1
ETABLE,MF_D,SMISC,2
ETABLE,MF_F,SMISC,15
PLLS,MF_D,MF_F
8.2.4.6 示例 5. 平面三维结构
图示
LOG
!
! 示例 5：影响线 - 三维平面结构
!
FINISH
~CFCLEAR,,1
/TITLE, 'CivilFEM影响线：框架'
~CODESEL,EC3,EC2 ! 设置欧洲 规范
~UNITS,SI ! 设置 国际单位制单位
/PREP7
!
! =========================== STEP 1: STRUCTURE DEFINITION
!
! 单元类型
ET,1,BEAM188,,,2
! 材料： EC3-钢
~CFMP,10,LIB,STEEL,EC3,Fe 360
! 梁截面
~SSECLIB,1,1,1,16 ! IPE 500（工字形）
~BMSHPRO,1,BEAM,1,1,,,188,0,0,,梁 1
! 实体建模
TYPE,1 $ MAT,10 $ SECNUM,1
! K 点
K, 1,-4, 8
K, 2, 4, 8
K, 3, 0, 0
K, 4, 0,14
K, 5, 0, 8
K, 6, 0, 4
K,100,100,100
! X 轴梁
L, 1, 5 $ L, 5, 2
! Y 轴梁
L, 3, 6 $ L, 6, 5 $ L, 5, 4
! 边界条件：固端支座
KSEL,S,KP,,1,4
DK,ALL,ALL,0
KSEL,ALL
! 划分网格
ESIZE,0.25 ! 单元尺寸
LATT,ALL,10,,1,,100,,1
LMESH,ALL
NSEL,ALL $ ESEL,ALL
!
! =========================== STEP 2: INFLUENCE LINE CALCULATION
!
! 目标节点
nn=NODE(kx(6),ky(6),0)
! 扭矩影响线 -----------------------------------------------
~ILOPEN,5,MY,FZ,nn,,,,1
/POST1
! 创建影响线图形
/VUP,ALL,Z
/VIEW,1,0,1
PLDISP,2
/PREP7
! 关闭影响线
! 剪力影响线 -----------------------------------------------
~ILOPEN,5,FY,FY,nn,,,,1
/POST1
! 创建影响线图形
/DSCA,ALL,10
PLDISP,2
/PREP7
! 关闭影响线
8.3 实体转板
8.3.1 简介
在有限元计算中，通常采用三维实体单元建立钢筋混凝土或预应力混凝土模型，其计算结果为单元节点处的应力。
然而，大多数情况下，各国所采用的规范都以内力作为计算依据，具体可采用梁内力或板壳内力，视情况而定。
CivilFEM提供了一个实用工具（SOLID SECTION），可对构件中获得的应力进行积分，将其等效为棱柱体后转换为梁内力。
该工具用于在由三维实体单元组成且可等效为板壳结构的结构中，获得采用以内力为依据的规范所需的内力。
8.3.2 初始数据
需要输入两类数据：
- 已通过三维实体单元定义的结构（完整结构或其一部分）。
- 定义板单元所需的信息。
待计算结构是第一项初始数据，应由以下两个组件定义：
- 构成结构某个表面（外表面或内表面）的节点。
- 构成该部分结构的所有单元。
附图说明了这些要求。
此外，为定义钢筋混凝土板，还必须提供所采用的保护层厚度和钢筋材料。
根据这些信息，CivilFEM将在三维结构的中面创建一个由SHELL181类型虚拟单元组成的新组件，并以此作为获取结构所需数据的基础。这些单元还将用于结果后处理。
虚拟SHELL单元被赋予板的材料和属性，这些材料和属性由CivilFEM根据实体结构的材料和厚度创建。所创建的材料不会为结构增加质量，以免干扰惯性或动力计算。
新的shell单元支承于独立于模型创建的节点（孤立节点）上。这些节点的所有自由度均受到约束。
此外，还将创建以下组件：
CF_SD2SH_NODES_#：包含编号为#的虚拟单元组中的节点的组件。
CF_SD2SH_ELEMENTS _#：包含编号为#的虚拟单元组中的单元的组件。
8.3.3 板厚度的获取
CivilFEM从外部单元表面的重心向该表面发射垂直射线，射线在结构的不同厚度单元（立方体、棱柱体或四面体）的两个面，即入口面和出口面，与附图中的点1和点2相交。
如果射线不垂直于出口面，CivilFEM将修正该射线的方向，使其方向为入口面和出口面法线方向的平均值。但是，如果射线从侧面而不是从相对表面射出，则射线方向将与该侧面平行。
在定义切割平面时，除了采用这些垂直方向外，还可以采用局部坐标轴系。此时，射线将沿该坐标系的Z轴方向，并根据该局部坐标轴系确定单元坐标轴系的方向。如果在某个单元中，该Z轴方向与入口面和出口面法线的平均方向相差超过5º，CivilFEM将在错误文件CF_SD2SH.ERR中指出这一点，并显示发生该warning的单元数量。
在此过程中，将获得结构在每个计算截面处的宽度d。该值可按照每种情况下提供的某一容差进行舍入，或舍入为给定值。如果用户在命令的可选参数TH中输入恒定厚度 ~SD2SH，且其某些单元中得到的厚度不一致，该情况将记录在错误文件 CF_SD2SH.ERR 中，并将提示发生该警告的单元数量。
如果由于某种原因程序无法创建某个单元，该情况将记录在错误文件 CF_SD2SH.ERR 中，并指出从其外表面生成 shell 单元的面实体单元编号。
8.3.4 应力张量的求取
在求取板厚的过程中，发射的射线在空间中定义计算点（在单元面上的进入点和出射点）。通过与限定这些面的节点应力张量进行插值，计算每个点处的应力张量。
由此得到一系列应力张量
，形式为
其中 n 为射线穿过的单元面数。
对于 SOLID65 单元，仅读取节点应力，不考虑所定义钢筋中的现有应力。
8.3.5 内力的求取
8.3.5.1 轴向力es
X 方向的轴向力计算如下
, t = 厚度方向
其中 di为各计算点到板单元中心的相应距离。
同样，y 方向为：
8.3.5.2 弯矩es
这是应力分布图相对于截面中心的静矩，即：
其中 x为该点到结构厚度中心的距离。其计算采用以下公式。
8.3.5.3 剪力
它们是应力的积分txy y tyz
8.3.5.4 切向力
根据以下表达式求得：
8.3.5.5 扭矩
根据以下表达式求得：
8.3.6 虚拟板单元的结果
虚拟板单元可以采用与结构中任何其他单元相同的方式进行后处理，但需要注意的是，其节点没有位移和应力结果。
由于这些单元具有内力结果，因此可以按照规范进行验算，验算数据将存储在结果文件中，以便像其他板单元一样进行后处理。
为了对结构进行配筋，程序需要知道板单元中钢筋的方向，因此这些单元的方向应设置为使其单元轴线与配筋方向一致。如果未使用命令的 CSYS 参数进行定向，则必须在板单元创建后定义该方向。
8.3.7 重新划分网格
为了提高该方法的精度，可以对虚拟板组的外部单元重新划分网格。重新划分网格的级别可为 1 至 3，其中级别 3 最为精细；在该级别下，每个外部单元根据其形状为三角形或四边形，分别划分为 26 个或 29 个新单元。这样可以增加获取结果的点数，并缩短与边界节点的距离，从而更精确地捕捉这些节点边界条件的影响。
8.4 混凝土松弛
8.4.1 简介介绍
该后处理方法用于考虑混凝土板裂缝截面的力学性能（以及应力重分布）。该过程可用于减小由变形相关荷载产生的力和弯矩。例如：
- 温度荷载
温度增量 Δ梁中的温度 T 产生变形： α. ΔT
在受约束模型中，该变形产生轴力：
N= A. E. ε
其与截面刚度 K= 成正比。= A. E
毛截面面积为： NGROSS= AGROSS. E. ε
开裂截面面积为： NCRACKED= A裂缝. E. ε
因此：NCRACKED= NGROSS
(A裂缝 /AGROSS)
- 基础沉降
同样地，在分析柱因转角 φ 产生的弯矩时：
弯矩与柱的刚度成正比：M= E.I.φ
毛截面面积为， MGROSS= E.IGROSS. φ
开裂截面面积为， MCRACKED= E.I裂缝. φ
因此：MCRACKED= MGROSS (I裂缝 /IGROSS)
8.4.2 初始数据
用户必须定义初始数据，即与变形相关的机械荷载，因此必须为每种荷载类型（机械荷载和应变相关荷载）定义不同的 load steps。
命令 ~CFFILE2, 5, Name, LS, SS 应用于向软件指示 用于降低变形相关荷载的机械荷载。Name 是结果文件的 名称，LS, SS，分别为 load step 和 substep。
8.4.3 开裂比计算
在第一次 迭代中，根据机械荷载计算各截面的开裂属性（中性轴、惯性矩 I1 和面积 S1)。根据机械荷载可获得各截面的这些值。如果 发生开裂，所得面积和惯性矩将小于初始的毛截面面积和惯性矩（I0 和 S0），这些值用于求解级别。
如果温度荷载在与机械荷载相同的截面侧引起开裂，即
弯矩符号相同，则计算新的变形相关荷载：
这些荷载通过弯矩乘以 I
比值获得1/ I0，轴力乘以 S 比值获得1/
S0。其数值由此降低为：
M1= M0 (I1/I0)
N1= N0 (S1/S0)
如果弯矩符号不同，温度荷载可能使裂缝闭合， 因此，在这种情况下采用毛截面更为保守：
M1= M0
N1= N0
随后进行迭代计算，在考虑折减内力 M 的情况下， 针对新的荷载组合重新计算惯性矩和面积1 y N1:
当满足以下条件时，模型收敛：
(Ii+1/Ii)< (1+tolerancia)，且 (Si+1/Si)< (1+tolerancia)。
8.4.4 如何使用结果
约化后的力和 弯矩结果将保存在 CivilFEM 结果文件中的新数据集中。要启动该过程并保存这些结果，请执行以下 步骤：
1- 使用以下命令设置初始数据（机械数据集）： ~CFFILE2.
2- 使用以下命令复制 ANSYS 中针对变形相关荷载的结果数据集RAPPND，并使用以下命令指定该 结果SET de ANSYS.
3- 使用以下命令启动应力重分布：~MOD_SF,,CONRELAX
结果将保存在 CivilFEM 中的新数据集中，其中包括弯曲和轴向受力两个方向的开裂比 （ratio_M_X、ratio_N_X、ratio_M_Y、ratio_N_Y），这些比值将用于 获得新的力和弯矩值：
|
Tx |
Tx* ratio_N_X |
|
Ty |
Ty* ratio_N_Y |
|
Txy |
Txy* MIN(ratio_N_X, ratio_N_Y) |
|
Mx |
Mx* ratio_M_X |
|
My |
My* ratio_M_Y |
|
Mxy |
Mxy* MIN(ratio_M_X, ratio_M_Y) |
|
Nx |
Nx* ratio_M_X |
|
Ny |
Ny* ratio_M_Y |