CFVR0957 - In-Plane Shear Calculation – ACI 349 06 Slab

Check of reinforcement for in-plane shear and membrane forces

To investigate the design of reinforcement for in-plane shear and membrane forces for ACI 349 06, a simple 5 ft x 25 ft x 1 ft slab model was used.
The 5-element model consists of Shell43 elements. Vertical and lateral loads were applied at nodes 3 and 8.
The wall is restrained at nodes 1 and 2 at the base of the model. Node 1 is restrained in the x, y, and z directions for translation as well as rotation in the x and z directions.
Node 2 is restrained in the y and z directions for translation as well as rotation in the x and z directions.

Element types used in the model: SHELL43

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

The example can be launched on an educational license.
KEYWORDS
Shell
Shell Vertex
Reinforced Concrete
ACI 349 06

Model Statistics
Number of elements 5
Number of nodes 12
Number of civil materials 2
Number of cross sections 0
Number of shell vertices 1

Log file: CFVR0957.DAT


 
FINISH
~CFCLEAR,,1
NomFile='CFVR0957'
/TITLE, %NomFile%,In-Plane Shear Calculation, ACI 349-01 Slab

~CODESEL,,ACI34906,,,
~UNITS,,LENG,IN 
~UNITS,,FORC,LBF
~UNITS,,PRES,,0 ,uuP
! ~CFCONFG,RESULT,CFSHF,1

!-------------------------------------------------------------------------------
! Model definition
!-------------------------------------------------------------------------------

THK    = 1*12.0 	! shell thickness 
COVER  = 0.8		! cover
WDTH   = 5*12.0		! wall width 
L      = 25*12.0	! wall heigth


/PREP7  
ET,1,SHELL43
~CFMP,1,LIB,CONCRETE,ACI,fc_6000
~CFMP,1,USER
~CFMP,1,ACI_C   ,fc_t    ,,6000 ,7,0,0  
~CFMP,2,LIB,REINF,ACI,fy_60000  

~SHLRNF,1,THK,1,2,COVER						! Bending Reinforcement
! ~SHLSHR, IVTX, MATOP,ASSOP, PHIOP, NXOP, NYOP, SXOP, SYOP, ASSOPX, ASSOPY
~SHLSHR,      1,     2,      ,      ,     ,     ,     ,     , 	! Shear Reinforcement
! ~SHLIPSH,IVTX, MATIP,ASSIPX, ASSIPY		
~SHLIPSH,     1,	 2,0.0605, 0.0605		! In-plane Reinforcement in2/in
~BMSHPRO,1,SHELL,1,1,1,1,43,,,,Shell 1

K,1
K,2,    ,,L
K,3,WDTH,,L
K,4,WDTH,,

A,1,2,3,4

TYPE,1
REAL,1
MAT,1

AESIZE,ALL,5*12.0, 
MSHAPE,0,2D 
MSHKEY,1 
AMESH,ALL   
LOCAL,11,0,-10,0,0,-180,-90, ,1,1,
EMODIF,ALL,ESYS,11,		! X Element horizontal, Y Element vertical
CSYS,0
/VIEW,1,,-1 

!-------------------------------------------------------------------------------
! Model resolution
!-------------------------------------------------------------------------------
FINISH
/SOLU

F,2,FX,140000
F,2,FY,80000
F,2,FZ,-40000

F,7,FX,140000
F,7,FY,80000
F,7,FZ,-40000

! Node 1 is restrained in x,y,z directions for translation 
! as well as rotation in the x and z directions
D,1, , , , , ,UX,UY,UZ,ROTX,ROTZ,
! Node 2 is restrained in y,z directions for translation 
! as well as rotation in the x and z directions
D,8, , , , , ,UY,UZ,ROTX,ROTZ, , 
ALLSEL
SOLVE

FINISH
/POST1

~CFSET,,1 
! Element # 1 is selected for design
ESEL,S,,,1
!~CHKCON,SHELL,IPSHEAR,, VAL1, VAL2, VAL3, 
~CHKCON, SHELL,IPSHEAR,,    3,     ,    1, ! VAL1=1-> Slabs with seismic loads, VAL3=1->Fi=0.75 

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
NComp = 6
NComp_ch = 0

 ! Matrix dim.
 *DIM,LABEL,CHAR,Ncomp,1
 *DIM,LABEL_CH,CHAR,Ncomp_ch,1
 *DIM,VALUE,,Ncomp,3
 *DIM,VALUE_CH,CHAR,Ncomp_ch,3
 *DIM,TOLER,,Ncomp,2   

! Labels
LABEL( 1,1) = 'CRT_1_Y'		! Example taken from ACI 349-01 Ch.21 (21.6.5.2)
LABEL( 2,1) = 'CRT_1_X'
LABEL( 3,1) = 'CRT_2_Y'		! Example taken from ACI 349-01 Ch.21 (21.6.5.6)
LABEL( 4,1) = 'CRT_2_X'
LABEL( 5,1) = 'CRT_3_Y'		! Example taken from ACI 349-01 Ch.21 (21.6.2.1,7.12.2)
LABEL( 6,1) = 'CRT_3_X'
  
! Correct values
~CFGET,Txy_Shell, ELEMENT, 1, FORCE,TXY, I   ! In-plane shear
! Slabs seismic design
VALUE( 1,1) = 1.1336
VALUE( 2,1) = 1.1336
VALUE( 3,1) = ABS(Txy_Shell/5577.1)
VALUE( 4,1) = ABS(Txy_Shell/5577.1)
VALUE( 5,1) = 0.0024/(0.0605/12)
VALUE( 6,1) = 0.0024/(0.0605/12)

! CivilFEM values     
~CFSET,1	! Slabs seismic design		
~CFGET,VALUE( 1,2), ELEMENT, 1 ,RESULT , CRT_1_Y, I 	
~CFGET,VALUE( 2,2), ELEMENT, 1 ,RESULT , CRT_1_X, I 
~CFGET,VALUE( 3,2), ELEMENT, 1 ,RESULT , CRT_2_Y, I 	
~CFGET,VALUE( 4,2), ELEMENT, 1 ,RESULT , CRT_2_X, I 
~CFGET,VALUE( 5,2), ELEMENT, 1 ,RESULT , CRT_3_Y, I 	
~CFGET,VALUE( 6,2), ELEMENT, 1 ,RESULT , CRT_3_X, I 	

! Warning and error tolerances
TOLER( 1,1)= 1E-2 $ TOLER( 1,2)= 1E-2 
TOLER( 2,1)= 1E-2 $ TOLER( 2,2)= 1E-2 
TOLER( 3,1)= 1E-2 $ TOLER( 3,2)= 1E-2 
TOLER( 4,1)= 1E-2 $ TOLER( 4,2)= 1E-2 
TOLER( 5,1)= 1E-2 $ TOLER( 5,2)= 1E-2 
TOLER( 6,1)= 1E-2 $ TOLER( 6,2)= 1E-2 

!-------------------------------------------------------------------------------
! Results comparison
!-------------------------------------------------------------------------------

COMPARA.MAC

Results

LabelTargetCivilFEMRatioTolerance
CRT_1_Y 1.1336 1.13361.000 0.01
CRT_1_X 1.1336 1.13361.000 0.01
CRT_2_Y 0.83676 0.836761.000 0.01
CRT_2_X 0.83676 0.836761.000 0.01
CRT_3_Y 0.47603 0.476031.000 0.01
CRT_3_X 0.47603 0.476031.000 0.01

Contains proprietary and confidential information of Ingeciber, S.A.