Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1

   NomFile='CFVR9117'
 /TITLE,%NomFile%, SHEAR DESIGN ACCORDING TO ACI 318 2019
! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~UNITS,,LENG,M
~UNITS,,TIME,S
~UNITS,,FORC,MP
~CODESEL,,ACI_19

! Preprocessor
  /PREP7

! Parameters
  L=10         ! Length between supports, in m
  b=.3         ! Cross-section width in m.
  h=.5         ! Depth in m.
  Q=4.5*1.5    ! Uniform distributed load in Mp/m

! Material Definition
 ~CFMP,1,LIB,CONCRETE,ACI,fc_4500
 ~CFMP,2,LIB,REINF,ACI,fy_60000
 ~CFMP,1,ACI_19_C,Lambda  ,,0.8


! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,0.5,0.3

! Reinforcement definition
 ~RNFDEF,1,1,2,4,,,0.6368E-02     ! Bot. reinf. for bending
 ~RNFDEF,1,2,2,2,,,0.2283E-02     ! Top reinf. for bending
 ~RNFDEF,1,SHEAR,2,,,.1E-4,       ! Shear reinf.
! Code properties
 ~SECMDF,1,ACIPROP ,D_Y,,0.45
 ~SECMDF,1,ACIPROP ,D_Z,,0.25
! Beam and Shell properties
  ~BMSHPRO,1,BEAM,1,,,,3,,,,Beam property

! Model Construction
  N,1                                   ! Nodes input
  N,21,L
  FILL,1,21
  E,1,2                                 ! Elements input
  EGEN,20,1,1,1
  D,1, , , , , ,UX,UY                   ! Boundary conditions
  D,21, , , , , ,UY



/SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE               ! Calculation


/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Shear in Y design according to ACI
  ~DIMCON,SHT,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 3
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'VC'
  LABEL(2,1) = 'VS'
  LABEL(3,1) = 'ASSH'

! Correct values
  VALUE(1,1)=10.182
  VALUE(2,1)=34.36
  VALUE(3,1)=0.00182

! Comparison
  ~CFGET,VALUE( 1,2),ELEMENT,20,RESULT,VC,J
  ~CFGET,VALUE( 2,2),ELEMENT,20,RESULT,VS,J
  ~CFGET,VALUE( 3,2),ELEMENT,20,RESULT,ASSH,J

! Warning and error tolerances
  TOLER(1,1)= 0.015*VALUE(1,1) $ TOLER(1,2)= 0.015*VALUE(1,1)
  TOLER(2,1)= 0.025*VALUE(2,1) $ TOLER(2,2)= 0.025*VALUE(2,1) 
  TOLER(3,1)= 0.02*VALUE(3,1) $ TOLER(3,2)= 0.02*VALUE(3,1) 


!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC