Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
  NomFile='CFVR2916'
 /TITLE,%NomFile%,SHEAR DESIGN ACCORDING TO SP-52-101-03

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KN
  ~CODESEL,,SP52101

! Preprocessor
  /PREP7

! Parameters
  L=5          ! Length between supports, in m
  Q=150        ! Uniform distributed load in kN/m

! Material Definition
~CFMP,1,LIB,CONCRETE,SP52101,B35
~CFMP,2,LIB,REINF,SP52101,A400  

! Element Type Definition
  ET,1,Beam3                               ! Element Type 1: 2D Beam

! Cross-section definition
~CSECDMS,1,REC,1,0.75,0.5
~SECMDF,1,SP52101P,REC,,0.05		! Mechanical cover for properties calculations   
~RNFDEF,1,SHEAR,2,,,1E-04       	! Shear Reinforcement=1cm2/m

! Beam properties
 ~BMSHPRO,1,BEAM,1,1,,,3,1,,,Beam Property

! Model Construction
  N,1                     ! Nodes input
  N,26,L
  FILL,1,26

  E,1,2                   ! Elements input
  EGEN,25,1,1,1

  D,1, , , , , ,UX,UY     ! Boundary conditions
  D,26,UY

/SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE                   ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Shear in Y design according to SP-52-101-03
  ~DIMCON,SHT,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 3
  NComp_ch = 0

 ! Matrix dim.
 *DIM,LABEL,CHAR,Ncomp,1
 *DIM,LABEL_CH,CHAR,Ncomp_ch,1
 *DIM,VALUE,,Ncomp,3
 *DIM,VALUE_CH,CHAR,Ncomp_ch,3
 *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'QB'
  LABEL(2,1) = 'QSW'
  LABEL(3,1) = 'ASSH'
  
! Correct values
  VALUE(1,1)=227.5
  VALUE(2,1)=147.5
  VALUE(3,1)=7.2433E-04
  
! Comparison
 ~PLLSCON,QB
  *GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,QSW
  *GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSCON,ASSH
  *GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_I

! Warning and error tolerances
  TOLER( 1, 1)= 1E-02 $ TOLER( 1, 2)= 1E-02
  TOLER( 2, 1)= 1E-02 $ TOLER( 2, 2)= 1E-02
  TOLER( 3, 1)= 1E-06 $ TOLER( 3, 2)= 1E-06
  
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC