CFVR1070 - Seismic margin in structural steel check according to EC3-05

Case of axial and biaxial bending.

A cantilever steel beam subjected to a Fx load of -500 kN, bending moment My of 30 kN*m and bending moment of 80 kN*m applied to free end.
The beam has a length of 1 m.
The cross section is a HE 200 B.
The beam is made of Fe 430 steel which has a fy of 275000 kN/m².
The aim of this example is to obtain the scale factor for permissible inelastic response (FSI) according to EN 1993-1-1:2005.

Element types used in the model: BEAM4

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

The example can be launched on an educational license.

KEYWORDS

Beam

Cross Section

Steel

Code Checking/Design

Eurocode 3

Model Statistics
Number of elements	1
Number of nodes	2
Number of civil materials	1
Number of cross sections	1
Number of shell vertices	0

Log file: CFVR1070.DAT

FINISH
~CFCLEAR,,1
NomFile='CFVR1070'
/TITLE,%NomFile%,Seismic margin in structural steel check according to EC3-05

! ------------------------------------------------------------------------------
! model definition and solution
! ------------------------------------------------------------------------------

! parameters
DUCT  = 1.3
FACT  = 0.35
FX_NS = -100.*FACT
MY_NS = 5.*FACT
MZ_NS = 20.*FACT
FX_S  = -500.*FACT
MY_S  = 30.*FACT
MZ_S  = 80.*FACT

~UNITS,,LENG,M
~UNITS,,TIME,S
~UNITS,,FORC,KN
~CODESEL,EC3-05,EC2-08,,,EC8-94

/PREP7

~CFMP,1,LIB,STEEL,EC3,Fe 430
~SSECLIB,1,1,6,6
~SECMDF,1,EC3PROP,DUCT,,DUCT
~BMSHPRO,1,BEAM,1,1,,,4,1,0
ET,1,BEAM4

N,1
N,25,1.
E,1,25
D,1,ALL

~CFSAVE,%NomFile%

FINISH

/FILNAME,NON_SEISMIC
~CFRESUM,%NomFile%

/SOLU

F,25,FX,FX_NS
F,25,MY,MY_NS
F,25,MZ,MZ_NS
SOLVE

FINISH

/FILNAME,SEISMIC
~CFRESUM,%NomFile%

/SOLU

F,25,FX,FX_S
F,25,MY,MY_S
F,25,MZ,MZ_S
SOLVE

FINISH

/FILNAME,NON_SEISMIC

/POST1

~CFSET,,1,1
~CFFILE2,4,SEISMIC.RCV
~HCLPFST,BEND_AXL,-Z,PARTIAL,,1,1
~PLSHCLP,FSE
~CFGET,FSE, ELEMENT, 1 ,RESULT ,  FSE, I, , , 1 
~CFSAVE,%NomFile%

FINISH

/FILNAME,SEISMIC_SCALED
~CFRESUM,%NomFile%

/SOLU

F,25,FX,FX_S*FSE
F,25,MY,MY_S*FSE
F,25,MZ,MZ_S*FSE
SOLVE

FINISH

/FILNAME,NON_SEISMIC

/POST1

~CFSET,,1,1
~CFFILE2,4,SEISMIC_SCALED.RCV
~HCLPFST,BEND_AXL,-Z,PARTIAL,,1,1

!-------------------------------------------------------------------------------
! data check
!-------------------------------------------------------------------------------

! arrays
NComp    = 2
NComp_ch = 0
*DIM,LABEL,CHAR,Ncomp,1
*DIM,LABEL_CH,CHAR,Ncomp_ch,1
*DIM,VALUE,,Ncomp,3
*DIM,VALUE_CH,CHAR,Ncomp_ch,3
*DIM,TOLER,,Ncomp,2

! labels
LABEL(1) = 'DUCT'
LABEL(2) = 'FSE'

! correct data
VALUE(1,1) = DUCT
VALUE(2,1) = 1.

! CivilFEM data
~CFGET,VALUE(1,2),SECTION,1,EC3PROP,DUCT
~PLSHCLP,FSE
~CFGET,VALUE(2,2), ELEMENT, 1 ,RESULT ,  FSE, I, , , 1 

! results comparison
TOLER(1,1) = 1.E-6*ABS(VALUE(1,1))
TOLER(1,2) = TOLER(1,1)
TOLER(2,1) = 5.E-2*ABS(VALUE(2,1))
TOLER(2,2) = TOLER(2,1)

COMPARA.MAC

Results

Label	Target	CivilFEM	Ratio	Tolerance
DUCT	1.3	1.3	1.000	1.3e-006
FSE	1	1	1.000	0.05

Contains proprietary and confidential information of Ingeciber, S.A.

CivilFEM Online Help

CFVR1070 - Seismic margin in structural steel check according to EC3-05

Case of axial and biaxial bending.

Results