CFVR2943 - Bending + Axial force design according to SP 63.13330.2012

Element types used in the model: BEAM4

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR2943'
 /TITLE,%NomFile%, BENDING + AXIAL FORCE DESIGN ACCORDING TO SP 63.13330.2012

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
 ~UNITS,,LENG,M
 ~UNITS,,TIME,S
 ~UNITS,,FORC,KN
 ~CODESEL,,SP63133

! Preprocessor
  /PREP7

! Material Definition
 ~CFMP,1,LIB,CONCRETE,SP63133,B20
 ~CFMP,2,LIB,REINF,SP63133,A400
 ~CFMP,2,SP_S    ,GAMs    ,,1.10 ! Changes gammaS in order to get same results than 52-101

! Element Type Definition
  ET,1,Beam4                            ! Element Type 1: 3D Beam

! Cross-section definition
 ~CSECDMS,1,BOX,1,0.85,1.2,0.2,0.15
! Reinforcement definition
 ~RNFDEF,1,1,2,4,0,0.05,1e-3            ! Total Reinf. Area= 1.3e-3 m^2
! Beam & Shell property
 ~BMSHPRO,1,BEAM,1,1,,,4,1,0,,Beam Property

! Model Construction
  N,1                                   ! Nodes input
  N,5,5
  FILL,1,5
  E,1,2                                 ! Elements input
  EGEN,4,1,1,1
  D,1,ALL                               ! Boundary conditions

/SOLU
  M=1800              ! 1800 kN*m bending moment
  F,5,MZ,M
  SOLVE               ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Bending + Axial design for circular sections according to SP 63.13330.2012
  ~DIMCON,2DB,,,5,10
!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 2
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2


! Labels
  LABEL(1,1) = 'CRTC2D_I'
  LABEL(2,1) = 'CRTC2D_J'

! Correct values
  VALUE(1,1)=1.000
  VALUE(2,1)=7.028

! Comparison
 ~PLLSCON,CRT_TOT
 *GET,VALUE(1,2),ELEM,4,ETAB,CFETAB_I
 ~PLLSCON,REINFACT
 *GET,VALUE(2,2),ELEM,4,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1, 1)= 1E-01 $ TOLER( 1, 2)= 1E-01
  TOLER( 2, 1)= 1E-01 $ TOLER( 2, 2)= 1E-01

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC