Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
   ~CFCLEAR,,1
   NomFile='CFVR7801'
   /TITLE, %NomFile%, AISC-LRFD13: Tension Checking L section
!--------------------------------------------------------------------------------------
! Model definition
!--------------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,IN
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KIPS! in, sec, Kips
  ~CODESEL,LRFD13
/PREP7
! Preprocessor
! --------------------------------------------------
! Materials
  ~CFMP,1,LIB,STEEL,ASTM,A36
! Element Types
  ET,1,BEAM3  ! Type 1: 2D Beam
! Cross Section
  ~SSECLIB,1,1,57,67   !L 4x4x1/2
  ~SECMDF,1,LRFD13PR,AHOLES  ,,0.87,0,0,0
! Beam & Shell Property
  ~BMSHPRO,1,BEAM,1,1,,,3,1,0,,Beam 1
! Nodes
  N,1
  N,21,,21
  FILL,1,21,19, , ,1,1,1,
! Elements
  REAL,1
  E,1,2
  EGEN,20,1,1,1

  /SOLU
! Solution
! --------------------------------------------------
! Constrains
  D, 1,ALL
! Apply Load
  F,21,FY,135
! Solve
  SOLVE

  /POST1
! Postprocessor
! --------------------------------------------------
! Read results
  ~CFSET,,1,1                  ! First load case
! Checking
  ~CHKSTL,TENSION

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 4
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2


! Labels
  LABEL(1,1) = 'FiPNG'
  LABEL(2,1) = 'FiPNE'
  LABEL(3,1) = 'FiPn'
  LABEL(4,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1)=121.5
  VALUE(2,1)=125.25
  VALUE(3,1)=121.5
  VALUE(4,1)=1.11

! Comparison
 ~PLLSSTL,FIPNG
 *GET,VALUE(1,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,FIPNE
 *GET,VALUE(2,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,FIPN
 *GET,VALUE(3,2),ELEM,1,ETAB,CFETAB_I
 ~PLLSSTL,CRT_TOT
 *GET,VALUE(4,2),ELEM,1,ETAB,CFETAB_I

! Warning and error tolerances
  TOLER( 1, 1)= 2E-02   $ TOLER( 1, 2)= 2E-02
  TOLER( 2, 1)= 5E-02   $ TOLER( 2, 2)= 5E-02  ! Rounding error accepted
  TOLER( 3, 1)= 2E-02   $ TOLER( 3, 2)= 2E-02
  TOLER( 4, 1)= 2E-02   $ TOLER( 4, 2)= 2E-02

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC