Element types used in the model: BEAM188

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

 FINISH
 ~CFCLEAR,,1
 NomFile='CFVR8694'
 /TITLE, %NomFile%, AISC15: Tension Check 
!--------------------------------------------------------------------------------------
! Model definition
!--------------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,IN
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KIPS! in, sec, Kips
  ~CODESEL,AISC15

! Parameters
  P  = 224		! Axial force kips
  Fyy = 50         ! ksi
  Fuu = 62         ! ksi

/PREP7
! Preprocessor
! --------------------------------------------------
! Materials
 ~CFMP,1,LIB,STEEL,ASTM,A36 
!  ASTM A500 Grade C
 ~CFMP,1,NAME,,,ASTM A500 Grade C
 ~CFMP,1,USER
 ~CFMP,1,AISC15  ,Fy,,Fyy ,1,0,0
 ~CFMP,1,AISC15  ,Fu,,Fuu ,1,0,0 
 
! Element Types
  ET,1,188  ! Type 1: 3D Beam
  
! Cross Section
  ~SSECLIB,1,1,61,246   ! HSS 6x4X3/8  
  ~SECMDF,1,MECHPROP,A        ,,6.18,2,0,0
  ~SECMDF,1,UPDATE
  aholes = 0.39 !  gap in fit-up between the HSS and the gusset plate
  ~SECMDF,1,AISC15PR,AHOLES  ,,aholes,0,0,0    ! area of holes  
  ! Shear leg factor is not included (always 1), so when Shear leg factor < 1, 
  ! net area must be modified to obtain the correcect effective net section 
  ~CFGET, AN, SECTION, 1, MECHPROP, A,, 3
  ~SECMDF,1,MECHPROP,A        ,,AN*0.90,3,0,0
  ~SECMDF,1,UPDATE
  
! Beam & Shell Property
  ~BMSHPRO,1,BEAM,1,1,,,188,1,0,,Beam 1
  
! Nodes
  N,1
  N,2,,2
  
! Elements
  SECNUM,1
  REAL,1
  E,1,2  

  /SOLU
! Solution
! --------------------------------------------------
! Constrains
  D,1,ALL
  
! Apply Load
  F,2,FY,P
  
! Solve
  SOLVE
  
  /POST1
! Postprocessor
! --------------------------------------------------
! Read results
  ~CFSET,,1                ! First load case
  
! Checking
 ~CHKSTL,TENSION,Z,LRFD    
 ~CHKSTL,TENSION,Z,ASD  
 
 !--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 6
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'FIPNG'
  LABEL(2,1) = 'FIPNE'
  LABEL(3,1) = 'FIPN'
  LABEL(4,1) = 'CLS_COMP'
  LABEL(5,1) = 'CRT_LRFD'
  LABEL(6,1) = 'CRT_ASD'

! Correct values
  VALUE(1,1)=278	          ! Tensile Yielding strength in gross section
  VALUE(2,1)=242              ! available tensile rupture strength 
  VALUE(3,1)=242              ! available tensile strength 
  VALUE(4,1)=1.00              ! 
  VALUE(5,1)=0.925            ! LRFD CRITERION   
  VALUE(6,1)=1.382             ! ASD CRITERION      

! Comparison

~CFSET,1   ! LRFD 
 ~CFGET,VALUE(1,2),ELEMENT,1,RESULT,FIPNG,I 
 ~CFGET,VALUE(2,2),ELEMENT,1,RESULT,FIPNE,I 
 ~CFGET,VALUE(3,2),ELEMENT,1,RESULT,FIPN,I 
 ~CFGET,VALUE(4,2),ELEMENT,1,RESULT,CLS_COMP,I
 ~CFGET,VALUE(5,2),ELEMENT,1,RESULT,CRT_TOT,I
 
~CFSET,2  ! ASD 
 ~CFGET,VALUE(6,2),ELEMENT,1,RESULT,CRT_TOT,I

! Warning and error tolerances
*DO,JJ,1,6
 TOLER(JJ,1)= 0.04*VALUE(JJ,1) $ TOLER(JJ,2)= 0.04*VALUE(JJ,1)
*ENDDO

  
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC