Element types used in the model: BEAM4, MASS21

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
  NomFile='CFVR1805'
  /TITLE, %NomFile%, NCSE94: Seismic Analysis (Simplified spectrum) Y-axis

! ----------------------------------------------------------------------
! Model definition
! ----------------------------------------------------------------------
! CivilFEM Setup: Code & Units
~UNITS,,LENG,CM
~UNITS,,TIME,S
~UNITS,,FORC,KP
~CODESEL,,,,,NCSE94
/PREP7
! Preprocessor
! ----------------------------------------------------------------------
! Materials: A-42
 ~CFMP,1,LIB,STEEL,EA,A42
! Modify density (Rho = 0)
 ~CFMP,1,USER
 ~CFMP,1,DatGen  ,RHO     ,,0
! Element Types
  ET,1,BEAM4   ! Type 1: 3D Beam
  ET,2,MASS21  ! Type 2: Mass
! Sections
 ~SSECLIB,1,1,1,1   !IPE 80
 ~BMSHPRO,1,BEAM,1,1,,,4,,0,,

! Nodes
  L = 10              ! L    : Bar length
  N, 1
  N,10,L

! Elements
  TYPE,1
  MAT ,1
  REAL,1
  EN,1,1,10
  EPLOT

! Parameters
  *GET,AR20,EX,1                         ! Ex   : Elastic Modulus
  ~CFGET,AR22,SECTION,1,MECHPROP,A,,2    ! Area : Bar area
  ~CFGET,AR23,SECTION,1,MECHPROP,IZZ,,2  ! Izz  : Moment of inertia
  ~CFGET,AR24,SECTION,1,MECHPROP,IYY,,2  ! Iyy  : Moment of inertia

! Spectrum definition
  ~DEFSPEC,ALL,0.13,I,DESIGN,50,1,4,4

  pi = 3.141592654

! ----------------------------------------------------------------------
! DATA CHECK
! ----------------------------------------------------------------------
! Data comparison number
  NComp = 40
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

*DO,ARG1,1,20
   /PREP7
   ~CFGET,AR26,SEISM,,SPEC,TH,,ARG1,1   ! Period
   ! Labels
   LABEL(ARG1,1) = 'Sa(%ARG1%)y'
   LABEL(20+ARG1,1) = 'Sa(%ARG1%)y'
   AR25=12*AR20*AR23/L**3     ! Bending stiffness around Z axis
   AR27=AR25*(AR26/(2*pi))**2  ! Mass applied at end
   R,2,0,AR27
   TYPE,2
   MAT, 1
   REAL,2
   EN,2,10
   FINISH
   /SOLU
 ! Solution
 ! ---------------------------------------------------------------------
 ! Displacements
   D,1,,,,,,ALL,,,,,
   D,10,,,,,UX, ,UZ,ROTX,ROTY,ROTZ,
   ~MODLSOL,1,
   ~CMBMOD,NONE,HORIZONT,NONE,0,0.0001,
 ! Query results
   *GET,ARG5,NODE,10,U,Y
 ! Correct values
   VALUE(20-ARG1+1,1)=ARG5*AR25/AR27 ! Acceleration
 ! Obtained values
   ~CFGET,VALUE(20-ARG1+1,2),SEISM,,SPEC,SDH,,ARG1,2	 ! Y components of design horizontal spectrum
   ~CFGET,VALUE(40-ARG1+1,2),SEISM,,SPEC,SDH,,ARG1,2	 ! Y components of design horizontal spectrum
   ! CivilFEM gives the spectrum Normalized by gravity.
   ! To compare it must be changed to user acceleration units.
   VALUE(20-ARG1+1,2) = VALUE(20-ARG1+1,2)*981
   VALUE(40-ARG1+1,2) = VALUE(40-ARG1+1,2)*981
   /PREP7
   EDELE,2
*ENDDO

! Correct values
! ----------------------------------------------------------------------
   VALUE(40,1) =  8.715
   VALUE(39,1) = 17.43
   VALUE(38,1) = 26.14
   VALUE(37,1) = 34.86
   VALUE(36,1) = 43.57
   VALUE(35,1) = 52.29
   VALUE(34,1) = 61.00
   VALUE(33,1) = 69.72
   VALUE(32,1) = 78.43
   VALUE(31,1) = 87.15
   VALUE(30,1) = 87.15
   VALUE(29,1) = 91.19
   VALUE(28,1) = 95.22
   VALUE(27,1) = 99.26
   VALUE(26,1) = 103.3
   VALUE(25,1) = 107.3
   VALUE(24,1) = 111.4
   VALUE(23,1) = 115.4
   VALUE(22,1) = 119.5
   VALUE(21,1) = 123.5

! Warning and error tolerances
! ----------------------------------------------------------------------
   *DO,II,1,40
     TOLER(II, 1)= 1E-01 $ TOLER(II, 2)= 1E-01
   *ENDDO

! ----------------------------------------------------------------------
! Results Comparison
! ----------------------------------------------------------------------
  COMPARA.MAC