Element types used in the model: BEAM188

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

! Table E.10. Analysis of HSS12x8x3/16 Column at Different Effective Lengths  (E-60)
 FINISH
 ~CFCLEAR,,1
 NomFile='CFVR8659'
 /TITLE, %NomFile%, AISC15: Compression Check 
!--------------------------------------------------------------------------------------
! Model definition
!--------------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,IN
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KIPS! in, sec, Kips
  ~CODESEL,AISC15

! Parameters
  P  = -510        ! Axial force kips
  Fyy = 50         ! ksi
  Fuu = 62         ! ksi

/PREP7
! Preprocessor
! --------------------------------------------------
! Materials
 ~CFMP,1,LIB,STEEL,ASTM,A36 
! ASTM A500 Grade C 
 ~CFMP,1,NAME,,,ASTM A500 Grade C
 ~CFMP,1,USER
 ~CFMP,1,AISC15  ,Fy,,Fyy ,1,0,0
 ~CFMP,1,AISC15  ,Fu,,Fuu ,1,0,0
 
! Element Types
  ET,1,188  ! Type 1: 3D Beam
  
! Cross Section HSS rectangular
  ~SSECLIB,1,1,61,161   !TS 12x8  
  ~SECMDF,1,NAME,,,HSS rectangular 12x8x3/16

! member property: pinned-pinned condition, effective length = 40 ft
  ~MEMBPRO,1,AISC15,ALL,40.00*12,1.00,1.00,1.000,1.000,40.00*12,  
   
! Beam & Shell Property
  ~BMSHPRO,1,BEAM,1,1,,,188,1,0,,Beam 1
  
! Area Update HSS rectangular 12x8x0.188
 ~SECMDF,1,MECHPROP,A        ,,6.760,2,0,0
 ~SECMDF,1,UPDATE
 ~UPDATE,BMSHPRO 
  
! Nodes
  N,1
  N,2,,2
  
! Elements
  SECNUM,1
  REAL,1
  E,1,2  

  /SOLU
! Solution
! --------------------------------------------------
! Constrains
  D,1,ALL
  
! Apply Load
  F,2,FY,P
  
! Solve
  SOLVE
  
  /POST1
! Postprocessor
! --------------------------------------------------
! Read results
  ~CFSET,,1                ! First load case
  
! Checking
 ~CHKSTL,COMPRESS,Z,LRFD   
 ~CHKSTL,COMPRESS,Z,ASD 
 
 !--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 6
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'FCR'
  LABEL(2,1) = 'PN'
  LABEL(3,1) = 'FE'
  LABEL(4,1) = 'CLS_COMP'
  LABEL(5,1) = 'CRT_LRFD'
  LABEL(6,1) = 'CRT_ASD'

! Correct values
  PI=acos(-1)
  VALUE(1,1)=12.2        ! Flexural buckling stress (Spec. Eq. E3-2) 
  VALUE(2,1)=82.5       ! Nominal Compressive Strength (Spec. Eq. E3-1)  
  VALUE(3,1)=(PI**2*29000)/(40*12/3.35)**2          ! Elastic  critical  buckling  stress (Spec. Eq. E3-4)  
  VALUE(4,1)=2.00         ! slender elements
  VALUE(5,1)=ABS(P/(0.90*82.5)) !         ! LRFD CRITERION 
  VALUE(6,1)=ABS(P/(82.5/1.67)) !         ! ASD CRITERION 

! Comparison

~CFSET,1   ! LRFD 
 ~CFGET,VALUE(1,2),ELEMENT,1,RESULT,FCR,I 
 ~CFGET,VALUE(2,2),ELEMENT,1,RESULT,PN,I 
 ~CFGET,VALUE(3,2),ELEMENT,1,RESULT,FE,I 
 ~CFGET,VALUE(4,2),ELEMENT,1,RESULT,CLS_COMP,I
 ~CFGET,VALUE(5,2),ELEMENT,1,RESULT,CRT_TOT,I
 
~CFSET,2  ! ASD 
 ~CFGET,VALUE(6,2),ELEMENT,1,RESULT,CRT_TOT,I

! Warning and error tolerances
*DO,JJ,1,6
 TOLER(JJ,1)= 0.03*VALUE(JJ,1) $ TOLER(JJ,2)= 0.03*VALUE(JJ,1)
*ENDDO
  
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC