CFVR2215 - Reinforced concrete design according to British Standard 8110

Element types used in the model: BEAM4

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

  FINISH
  ~CFCLEAR,,1
  NomFile='CFVR2215'
  /TITLE, %NomFile%, BENDING + AXIAL FORCE DESIGN ACCORDING TO BS8110

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,MP
  ~CODESEL,,BS8110

! Preprocessor
  /PREP7

! Material Definition
  ~CFMP,1,LIB,CONCRETE,BS8110,C25
  ~CFMP,2,LIB,REINF,BS8110,Gr460A

! Element Type Definition
  ET,1,Beam4                            ! Element Type 1: 3D Beam

! Cross-section definition
  ~CSECDMS,1,PIPE,1,0.6,0.15

! Reinforcement definition
  ~RNFDEF,1,1,2,1,0,0.046,1e-3          ! Total Reinf.area=10cm^2

! Beam & Shell property
  ~BMSHPRO,1,BEAM,1,1,,,4,1,0,,Beam property

! Model
  N,1
  N,5,5
  FILL,1,5
  E,1,2
  EGEN,4,1,1,1
! Boundary conditions
  D,1,ALL,0

/SOLU
! Solution
  M=52.620            ! 52.620 m*Mp bending moment
  H=-70.820           ! 70.820 Mp axial force
  F,5,FX,H
  F,5,MZ,M
  SOLVE               ! Calculation

/POST1
! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Bending + Axial design
  ~DIMCON,3DB,,,2,8

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparision number
  NComp = 2
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
! Labels
  LABEL(1,1) = 'CRT_TOT'
  LABEL(2,1) = 'REINFACT'

! Correct Values
  VALUE(1,1) = 1.00
  VALUE(2,1) = 5.50

! Comparison
 ~PLLSCON,CRT_TOT
 *GET,VALUE(1,2),ELEM,4,ETAB,CFETAB_I
 ~PLLSCON,REINFACT
 *GET,VALUE(2,2),ELEM,4,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1,1)= 1E-3 $ TOLER( 1,2)= 1E-3
  TOLER( 2,1)= 1E-2 $ TOLER( 2,2)= 1E-2

!--------------------------------------------------------------------------------------
! Results Comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC