Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
  NomFile='CFVR1436'
 /TITLE,%NomFile%, SHEAR CHECKING ACCORDING TO EHE-08

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
~UNITS,,LENG,m
~UNITS,,TIME,S
~UNITS,,FORC,MP
~CODESEL,EC3-92,EHE-08,,,EC8-94

! Preprocessor
  /PREP7

! Parameters
  L=10         ! Length between supports, in m
  b=.3         ! Cross-section width in m.
  h=.5         ! Depth in m.
  Q=4.5*1.5    ! Uniform distributed load in Mp/m

! Material Definition
 ~CFMP,1,LIB,CONCRETE,EHE,HA-35
 ~CFMP,2,LIB,REINF,EHE,B400S

! Element Type Definition
  ET,1,Beam3                            ! Element Type 1: 2D Beam

! Cross-section definition
 ~CSECDMS,1,REC,1,0.5,0.3

! Reinforcement definition
 ~RNFDEF,1,1,2,4,,0.050,0.6368E-02          ! Bot. reinf. for bending
 ~RNFDEF,1,2,2,2,,0.050,0.2283E-02          ! Top reinf. for bending
 ~RNFDEF,1,SHEAR,2,,,,,,,4.416e-002,6,2,2

! Code properties definition
  ~SECMDF,1,EHEPROP,REC ,,5e-002
  ~SECMDF,1,EHEPROP,Rho1,,0.02

! Beam properties
  ~BMSHPRO,1,BEAM,1,,,,3,,,,Beam Prop.

! Model Construction
  N,1 
  N,21,L
  FILL,1,21
  E,1,2
  EGEN,20,1,1,1
  D,1, , , , , ,UX,UY
  D,21, , , , , ,UY

  /SOLU
  SFBEAM,ALL,1,PRES,Q
  SOLVE               ! Calculation

/POST1

! Postprocessor
  ~CFSET,,1,1       ! Read first load step

! Shear in Y checking according to EHE
  ~CHKCON,SHT,SHEAR

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 4
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
!--------------------------------------------------------------------------------------
  LABEL(1,1) = 'VU1'
  LABEL(2,1) = 'VSU'
  LABEL(3,1) = 'VCU'
  LABEL(4,1) = 'CRT_TOT'

! Correct values
  VALUE(1,1)=96.36
  VALUE(2,1)=18.40
  VALUE(3,1)=9.456
  VALUE(4,1)=1.212

! Comparison
 ~PLLSCON,VU1
 *GET,VALUE(1,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,VSU
 *GET,VALUE(2,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,VCU
 *GET,VALUE(3,2),ELEM,20,ETAB,CFETAB_J
 ~PLLSCON,CRT_TOT
 *GET,VALUE(4,2),ELEM,20,ETAB,CFETAB_J

! Warning and error tolerances
  TOLER( 1, 1)= 1E-02 $ TOLER( 1, 2)= 1E-02
  TOLER( 2, 1)= 1E-00 $ TOLER( 2, 2)= 1E-00
  TOLER( 3, 1)= 1E-01 $ TOLER( 3, 2)= 1E-01
  TOLER( 4, 1)= 1E-01 $ TOLER( 4, 2)= 1E-01

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC