Element types used in the model: BEAM188

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

 FINISH
 ~CFCLEAR,,1
 NomFile='CFVR8669'
 /TITLE, %NomFile%, AISC15: Bending Check 
!--------------------------------------------------------------------------------------
! Model definition
!--------------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,IN
  ~UNITS,,FORC,KIPS! in, sec, Kips
  ~CODESEL,AISC15

! Parameters
  M   = 6.12*12     ! Moment kip-in
  Fyy = 50        ! ksi
  Fuu = 62        ! ksi

/PREP7
! Preprocessor
! --------------------------------------------------
! Materials
 ~CFMP,1,LIB,STEEL,ASTM,A36 
!  ASTM A500 Grade C 
 ~CFMP,1,NAME,,,ASTM A500 Grade C 
 ~CFMP,1,USER
 ~CFMP,1,AISC15  ,Fy,,Fyy ,1,0,0
 ~CFMP,1,AISC15  ,Fu,,Fuu ,1,0,0
 
! Element Types
  ET,1,188  ! Type 1: 3D Beam
  
! Cross Section 
  ~SSECLIB,1,1,61,188   !TS 10x6  noncompact flanges and compact webs.
  
! member property: Cb=1.14
  ~MEMBPRO,1,AISC15,ALL,21*12,1.00,1.00,1.00,1.14,21*12,  

! Beam & Shell Property
  ~BMSHPRO,1,BEAM,1,1,,,188,1,0,,Beam 1

! Update section data 
  ~SECMDF,1,MECHPROP,A        ,,5.37,  2,0,0
  ~SECMDF,1,MECHPROP,IZZ      ,,74.6,  2,0,0
  ~SECMDF,1,MECHPROP,IYY      ,,34.1,  2,0,0
  ~SECMDF,1,MECHPROP,IZ       ,,3.73,  2,0,0
  ~SECMDF,1,MECHPROP,IY       ,,2.52,  2,0,0
  ~SECMDF,1,MECHPROP,WZ       ,,14.9,  2,0,0
  ~SECMDF,1,MECHPROP,WY       ,,11.4,  2,0,0
  ~SECMDF,1,MECHPROP,ZWS      ,,1.575, 2,0,0   
  ~SECMDF,1,MECHPROP,YWS      ,,3.392, 2,0,0   
  ~SECMDF,1,MECHPROP,IXX      ,,73.8,  2,0,0
  ~SECMDF,1,MECHPROP,XWT      ,,20.349,2,0,0  
  ~SECMDF,1,MECHPROP,WPZ      ,,18    ,2,0,0 
  ~SECMDF,1,MECHPROP,WPY      ,,12.7  ,2,0,0
  ~UPDATE,BMSHPRO 
  
! Nodes
  N,1
  N,2,,2
  
! Elements
  SECNUM,1
  REAL,1
  E,1,2  

/SOLU
! Solution
! --------------------------------------------------
! Constrains
  D,1,ALL
  
! Apply Load
  F,ALL,MZ,M  
  
! Solve
  SOLVE
  
/POST1
! Postprocessor
! --------------------------------------------------
! Read results
  ~CFSET,,1                ! First load case
 
! Checking
  ~CHKSTL,BENDING,Z,LRFD  
  ~CHKSTL,BENDING,Z,ASD  
 
!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 14
  NComp_ch = 0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
  LABEL(1,1) = 'MU'
  LABEL(2,1) = 'MP'
  LABEL(3,1) = 'MN_YLD'
  LABEL(4,1) = 'MN_LTB'  
  LABEL(5,1) = 'MN_FLB'
  LABEL(6 ,1) = 'CLS_BEND'
  LABEL(7 ,1) = 'CRT_LRFD'
  LABEL(8 ,1) = 'CRT_ASD'
  LABEL(9 ,1) = 'CRT_YLDL'  
  LABEL(10,1) = 'CRT_LTBL'    
  LABEL(11,1) = 'CRT_FLBL'  
  LABEL(12,1) = 'CRT_YLDA'  
  LABEL(13,1) = 'CRT_LTBA'       
  LABEL(14,1) = 'CRT_FLBA'  

! Correct values
  VALUE(1,1)= 73.44              ! required flexural strength
  VALUE(2,1)= 900            ! Plastic bending moment  
  VALUE(3,1)= 900            ! Nominal Flexural Strength for yielding limit state
  VALUE(4,1)= 900           ! Nominal Flexural Strength for lateral-torsional buckling limit state
  VALUE(5,1)= 796            ! Nominal flexure strength for Flange Local Buckling limit state
  VALUE(6 ,1)= 2.00          ! the flange is noncompact 
  VALUE(7 ,1)= 0.1025   ! LRFD CRITERION   
  VALUE(8 ,1)= 0.154   ! ASD  CRITERION   
  VALUE(9 ,1)= 0.0906   ! Yielding CRITERION LRFD   
  VALUE(10,1)= 0.0906  ! lateral-torsional buckling limit state CRITERION LRFD    
  VALUE(11,1)= 0.1025   ! flange local buckling limit state CRITERION LRFD      
  VALUE(12,1)= 0.136   ! Yielding CRITERION ASD   
  VALUE(13,1)= 0.136   ! lateral-torsional buckling limit state CRITERION ASD     
  VALUE(14,1)= 0.154  ! flange local buckling limit state CRITERION ASD    
  
! Comparison

~CFSET,1   ! LRFD 
 ~CFGET,VALUE(1,2),ELEMENT,1,RESULT,MU,I 
 ~CFGET,VALUE(2,2),ELEMENT,1,RESULT,MP,I 
 ~CFGET,VALUE(3,2),ELEMENT,1,RESULT,MN_YLD,I  
 ~CFGET,VALUE(4,2),ELEMENT,1,RESULT,MN_LTB,I   
 ~CFGET,VALUE(5,2),ELEMENT,1,RESULT,MN_FLB,I  
 ~CFGET,VALUE(6 ,2),ELEMENT,1,RESULT,CLS_BEND,I
 ~CFGET,VALUE(7 ,2),ELEMENT,1,RESULT,CRT_TOT,I
 ~CFGET,VALUE(9 ,2),ELEMENT,1,RESULT,CRT_YLD,I
 ~CFGET,VALUE(10,2),ELEMENT,1,RESULT,CRT_LTB,I    
 ~CFGET,VALUE(11,2),ELEMENT,1,RESULT,CRT_FLB,I     
 
~CFSET,2  ! ASD 
 ~CFGET,VALUE(8,2),ELEMENT,1,RESULT,CRT_TOT,I
 ~CFGET,VALUE(12,2),ELEMENT,1,RESULT,CRT_YLD,I
 ~CFGET,VALUE(13,2),ELEMENT,1,RESULT,CRT_LTB,I    
 ~CFGET,VALUE(14,2),ELEMENT,1,RESULT,CRT_FLB,I    

! Warning and error tolerances
*DO,JJ,1,14
 TOLER(JJ,1)= 0.04*VALUE(JJ,1) $ TOLER(JJ,2)= 0.04*VALUE(JJ,1)
*ENDDO
  
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC