CFVR1012 - EC3-2005 test: Pure bending

Bending checking according to EN 1993-1-1:2005

A pinned-pinned steel beam is subjected to a surface load of 2.75 kN/m.
The beam has a length of 12 m. the cross section is a IPE 200.
The beam is made of Fe 430 steel which has a fy of 275000 kN/m².
The aim of the example is to obtain the cross section classification, and bending checking criterion according to EN 1993-1-1:2005.

Element types used in the model: BEAM3

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

The example can be launched on an educational license.

KEYWORDS

Beam

Cross Section

Steel

Code Checking/Design

Eurocode 3

Model Statistics
Number of elements	24
Number of nodes	25
Number of civil materials	1
Number of cross sections	1
Number of shell vertices	0

Log file: CFVR1012.DAT

   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR1012'
  /TITLE, %NomFile%, EC3-2005 test: Pure bending

! ---------------------------------------------------------------------------------
! Model definition and solve
! ---------------------------------------------------------------------------------
! CivilFEM Setup: Code & Units
  ~UNITS,,LENG,M
  ~UNITS,,TIME,S
  ~UNITS,,FORC,KN
  ~CODESEL,EC3-05,EC2-08,,,EC8-94

/PREP7
! Materials
  ~CFMP,1,LIB,STEEL,EC3,Fe 430   ! Fe 430 (EC3)

! Element Types
  ET,1,Beam3
! Cross Sections
  ~SSECLIB,1,1,1,7   ! IPE 200

! Beam & Shell properties
  ~BMSHPRO,1,BEAM,1,1,,,3,1,0,

! Nodes
  N, 1
  N,25,12
  FILL, 1,25
! Elements
  E,1,2
  EGEN,24,1,1
  
/SOLU
! Restraints
  D, 1,UX
  D, 1,UY
  D,25,UY
! Apply Load
  SFBEAM,ALL,1,PRES,2.75
! Solve
  SOLVE

/POST1
! Read results
  ~CFSET,,1,1       ! Read the first load step
! Check for Bending
  ~CHKSTL,BENDING,-Z,PARTIAL 

!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
  NComp    =  5
  NComp_ch =  0

! Marix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
!--------------------------------------------------------------------------------------
  LABEL(1,1) = 'CLASS'
  LABEL(2,1) = 'MEd'
  LABEL(3,1) = 'McRd'
  LABEL(4,1) = 'W'
  LABEL(5,1) = 'CRT_TOT'
! Correct values
!--------------------------------------------------------------------------------------
  VALUE(1,1)=1
  VALUE(2,1)=-49.5
  VALUE(3,1)=55.15
  VALUE(4,1)=220.6E-6 
  VALUE(5,1)=0.89755

! Obtained values
!--------------------------------------------------------------------------------------
 
 ~CFGET,VALUE( 1,2),ELEMENT,13,RESULT,CLASS,I
 ~CFGET,VALUE( 2,2),ELEMENT,13,RESULT,MED,I
 ~CFGET,VALUE( 3,2),ELEMENT,13,RESULT,MCRD,I
 ~CFGET,VALUE( 4,2),ELEMENT,13,RESULT,W,I
 ~CFGET,VALUE( 5,2),ELEMENT,13,RESULT,CRT_TOT,I

! Warning and error tolerances
  TOLER( 1, 1)= 0    $ TOLER( 1, 2)= 0
  TOLER( 2, 1)= 1E-4 $ TOLER( 2, 2)= 1E-4
  TOLER( 3, 1)= 1E-2 $ TOLER( 3, 2)= 1E-2
  TOLER( 4, 1)= 1E-6 $ TOLER( 4, 2)= 1E-6
  TOLER( 5, 1)= 1E-2 $ TOLER( 5, 2)= 1E-2
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC

Results

Label	Target	CivilFEM	Ratio	Tolerance
CLASS	1	1	1.000	0
MEd	-49.5	-49.5	1.000	0.0001
McRd	55.15	55.15	1.000	0.01
W	0.0002206	0.0002206	1.000	1e-006
CRT_TOT	0.89755	0.89755	1.000	0.01

Contains proprietary and confidential information of Ingeciber, S.A.

CivilFEM Online Help

CFVR1012 - EC3-2005 test: Pure bending

Bending checking according to EN 1993-1-1:2005

Results