CFVR1227 - Biaxial Bending + Axial force checking according to Eurocode 2 (1991)

Element types used in the model: BEAM4

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

 FINISH
  ~cfclear,,1
   NomFile='CFVR1227'
 /TITLE,%NomFile%, Biaxial BENDING + AXIAL FORCE CHECKING EC2

! -------------------------------------------------------------------------------------
! Initial data
! -------------------------------------------------------------------------------------
! CivilFEM SETUP
 ~UNITS,,LENG,M
 ~UNITS,,TIME,S
 ~UNITS,,FORC,MP
 ~CODESEL,EC3-92,EC2-91,EC2-91,,EC8-94
 
! Parameters
 *DIM,Dir,CHAR,2
 *DIM,Moment,ARRAY,2
 *DIM,CRT_3D,ARRAY,2
 *DIM,CRT_2D,ARRAY,2
 Dir(1)='Z','Y'
 Moment(1)=30.0,40.0
 
! CivilFEM Preprocessor
  /PREP7

! Material Definition
 ~CFMP,1,LIB,CONCRETE,EC2,C25/30
 ~CFMP,2,LIB,REINF,EC2,S500

! Element Type Definition
  ET,1,Beam4                            ! Element Type 1: 3D Beam

! Cross-section definition
 ~CSECDMS,1,T,1,0.5,0.2,0.45,0.15

! Reinforcement definition
 ~RNFDEF,1,1,2,2,0,0.046,0.5120E-02
! Beam & Shell property
 ~BMSHPRO,1,BEAM,1,1,,,4,1

! Model Construction
  N,1                                   ! Nodes input
  N,5,5
  FILL,1,5
  E,1,2                                 ! Elements input
  EGEN,4,1,1,1
  D,1,ALL                               ! Boundary conditions
	  
*DO,II,1,2
 /SOLU
  FDELE,ALL,ALL
  F,5,M%Dir(II)%,Moment(II)
  SOLVE               ! Calculation
  
/POST1             
! CivilFEM Postprocessor
  ~CFSET,,1           !Read first load step

! Bending + Axial checking according to EC2 (3DB)
  ~CHKCON,3DB
  ~PLLSCON,CRT_TOT
  *GET,CRT_3D(II),ELEM,4,ETAB,CFETAB_I
  
! Bending + Axial checking according to EC2 (2DB)
 ~CHKCON,2DB,,II-1
 ~PLLSCON,CRT_TOT
  *GET,CRT_2D(II),ELEM,4,ETAB,CFETAB_I
 *ENDDO
 
!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 2
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2
  
  *DO,II,1,NComp

! Labels
  LABEL(II,1) = 'CRT3D_%II%'
  
! Correct values
  VALUE(II,1)=CRT_2D(II)

! Comparison
  VALUE(II,2)=CRT_3D(II)

! Warning and error tolerances
   TOLER( II, 1)= 1.0E-01 $ TOLER( II, 2)= 1.0E-01
  
  *ENDDO

!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC