CFVR2956 - Shell crack check according to SP63133 (bending+axial compression)

Element types used in the model: SHELL_181

Needed CivilFEM Modules:
Geotechnical Module
Bridges and Civil Non Linearities Module
Advanced Prestressed Concrete Module

   FINISH
  ~CFCLEAR,,1
   NomFile='CFVR2956'
  /TITLE, %NomFile%, Shell crack check according to SP63133 (bending+axial compression)

! ------------------------------------------------------------------------------
! Model definition and solve
! ------------------------------------------------------------------------------

! Parameters
   PI=3.1415926
   A = 3
   B = 6
   T = 0.2         ! Thickness
   R = 0.03        ! Cover 
   Asb=6.296e-3
   Ast=3.0708e-3
   SXT = 0.2
   SXB = 0.2
   SYT = 0.2
   SYB = 0.2
   PHIXT  = 2*SQRT(Ast*SXT/PI)*1e3 !mm
   PHIXB = 2*SQRT(Asb*SXB/PI)*1e3 !mm
   PHIYT = 2*SQRT(Ast*SYT/PI)*1e3 !mm
   PHIYB = 2*SQRT(Asb*SYB/PI)*1e3 !mm
   EsIZ = 0.25
   Q = 60
   H = 200

   
! Code
~CODESEL,,SP63133,

! Units
 ~UNITS,,FORC,KN 
  
/PREP7
! Material
~CFMP,1,LIB,CONCRETE,SP63133,B25
~CFMP,2,LIB,REINF,SP63133,A400  
  
! Element types
ET,1,181
   
! Shell Vertex 
~SHLRNF,1,T,1,2,,,,,,0,0.000,45.00,SXT,PHIXT,SXB,PHIXB,SYT,PHIYT,SYB,PHIYB,R,R,R,R 
 

! Shell properties
~BMSHPRO,1,SHELL,1,1,1,1, 181,,, ,Shell 1   
  
! Geometry
RECTNG,0,A,0,B
  
! Mesh
AESIZE,1,EsIZ,  
AMESH,1
  
FINISH
/SOLU 
 
! BCs
NSEL,S,LOC,X,0
NSEL,A,LOC,X,A
D,ALL,UX  
NSEL,S,LOC,Y,0
D,ALL, , , , , ,UX,UY,UZ,ROTZ, ,   
NSEL,S,LOC,Y,B
D,ALL, , , , , ,UX,UZ,ROTZ, , ,
ALLSEL
  

! Vertical Pressure
SFE,ALL,1,PRES, ,-Q

! Compression pressure to forces
NSEL,S,LOC,Y,B
*GET,NNODE,NODE,,COUNT
F,ALL,FY,-H*A/NNODE

ALLSEL
SOLVE

FINISH
/POST1

~CFSET,,1

~CHKCON,SHELL,CRACK, ,0.0003,1.0,0.5,1.0
~CFSET,1
 
!--------------------------------------------------------------------------------------
! DATA CHECK
!--------------------------------------------------------------------------------------
! Data comparison number
  NComp = 7
  NComp_ch = 0

! Matrix dim.
  *DIM,LABEL,CHAR,Ncomp,1
  *DIM,LABEL_CH,CHAR,Ncomp_ch,1
  *DIM,VALUE,,Ncomp,3
  *DIM,VALUE_CH,CHAR,Ncomp_ch,3
  *DIM,TOLER,,Ncomp,2

! Labels
!--------------------------------------------------------------------------------------
  LABEL(1 ) = 'MCRT_Y'
  LABEL(2 ) = 'CRT_MY'
  LABEL(3 ) = 'X_M_Y'
  LABEL(4 ) = 'ABT_Y'
  LABEL(5 ) = 'LS_Y'
  LABEL(6 ) = 'ACRC_Y'
  LABEL(7 ) = 'CRTTOT_Y'


! Correct values
  VALUE(1 ,1)= 28.6
  VALUE(2 ,1)= 9.55
  VALUE(3 ,1)= 0.098
  VALUE(4 ,1)= 0.1
  VALUE(5 ,1)= 0.4
  VALUE(6 ,1)= 0.275E-3
  VALUE(7 ,1)= 0.916
 
 
! Comparison
 ~CFSET,1
 ~CFGET,VALUE(1 ,2),ELEMENT,145,RESULT,MCRT_Y,I
 ~CFGET,VALUE(2 ,2),ELEMENT,145,RESULT,CRT_MY,I
 ~CFGET,VALUE(3 ,2),ELEMENT,145,RESULT,X_M_Y,I
 ~CFGET,VALUE(4 ,2),ELEMENT,145,RESULT,ABT_Y,I
 ~CFGET,VALUE(5 ,2),ELEMENT,145,RESULT,LS_Y,I
 ~CFGET,VALUE(6 ,2),ELEMENT,145,RESULT,ACRC_Y,I
 ~CFGET,VALUE(7 ,2),ELEMENT,145,RESULT,CRTTOT_Y,I


  ! Warning and error tolerances
TOLER( 1,1)= VALUE(1 ,1)*1E-2 $ TOLER( 1,2)= VALUE(1 ,1)*1E-2 
TOLER( 2,1)= VALUE(2 ,1)*1E-2 $ TOLER( 2,2)= VALUE(2 ,1)*1E-2 
TOLER( 3,1)= VALUE(3 ,1)*1E-2 $ TOLER( 3,2)= VALUE(3 ,1)*1E-2
TOLER( 4,1)= VALUE(4 ,1)*1E-2 $ TOLER( 4,2)= VALUE(4 ,1)*1E-2
TOLER( 5,1)= VALUE(5 ,1)*1E-2 $ TOLER( 5,2)= VALUE(5 ,1)*1E-2
TOLER( 6,1)= VALUE(6 ,1)*3E-2 $ TOLER( 6,2)= VALUE(6 ,1)*3E-2
TOLER( 7,1)= VALUE(7 ,1)*3E-2 $ TOLER( 7,2)= VALUE(7 ,1)*3E-2
  
!--------------------------------------------------------------------------------------
! Results comparison
!--------------------------------------------------------------------------------------
  COMPARA.MAC